Debian Codegraph @

test/dapltest/scripts/dt-cli.bat

raw
1 @echo off
2 rem
3 rem Sample DAPLtest client Usage: dt-cli.bat provider hostname testname [-D]
4 rem
5
6 SETLOCAL
7
8 rem cmd.exe /V:on (delayed environment variable expansion) is required!
9 rem restart with /V:on if necessary
10 set F=on
11 set F=off
12 if not "!F!" == "off" (
13 %comspec% /E:on /V:on /C %0 %1 %2 %3 %4
14 if ERRORLEVEL 2 (exit /B %ERRORLEVEL%) else (exit /B 0)
15 )
16
17 rem set DAT_OVERRIDE=D:\dapl2\dat.conf
18 rem favor DAT 2.0 (dapl2test.exe) over DAT 1.1 (dapltest.exe)
19
20 set DT=dapl2test.exe
21 %DT% -h > Nul 2>&1
22 if not "%ERRORLEVEL%" == "1" (
23 echo %0: ERR - %DT% not in exec path?
24 exit /B %ERRORLEVEL%
25 )
26 rem To debug dapl2test - use dapl2testd.exe with ibnic0v2d
27
28 rem setup DAPL provider name: translate shorthand name or use name from dat.conf.
29 rem if DAPL provider name is incorrect, DAPL will fail correctly.
30
31 if "%1" == "" goto usage
32 if "%1" == "ibal" set D=ibnic0v2
33 if "%1" == "ibal0" set D=ibnic0v2
34 if "%1" == "ibal1" set D=ibnic1v2
35 if "%1" == "scm" set D=ibnic0v2-scm
36 if "%1" == "cma" set D=ibnic0v2-cma
37 if "%D%" == "" set D=%1
38
39 rem DaplTest server hostname
40 if "%2" == "" goto usage
41 set S=%2
42
43 rem Which test ?
44 if "%3" == "" goto usage
45 set T=%3
46
47 set LPS=5
48
49 rem Enable DEBUG?
50
51 if "%4" == "-D" (set X=0xffff) else set X=
52 if not "%X%" == "" (
53 set DAT_OS_DBG_TYPE=%X%
54 set DAT_DBG_TYPE=%X%
55 set DAT_DBG_LEVEL=%X%
56 set DAPL_DBG_LEVEL=%X%
57 set DAPL_DBG_TYPE=%X%
58 ) else (
59 rem set DAT_DBG_TYPE=0x1
60 rem set DAT_DBG_LEVEL=1
61 )
62
63 if "%4" == "-Q" ( set QUIET=1 ) else ( set QUIET=0 )
64
65 rem %DT% -T T -V -t 2 -w 2 -i 1000111 -s %S% -D %D%
66 rem client RW 4096 1 server RW 2048 4
67 rem client RR 1024 2 server RR 2048 2
68 rem client SR 1024 3 -f server SR 256 3 -f
69
70 rem %DT% -T T -P -t 1 -w 1 -i 1024 -s %S% -D %D%
71 rem client RW 4096 1 server RW 2048 4
72 rem server RR 1024 2 client RR 2048 2
73 rem client SR 1024 3 -f server SR 256 3 -f
74
75 if "%T%" == "bench" (
76 echo %T%: Threads[1] Endpoints[1] transactions[RW, RR, SR], 64K iterations
77 set STIME=!DATE! !TIME!
78 %DT% -T T -P -t 1 -w 1 -i 65536 -s %S% -D %D% client RW 4096 4 server RW 2048 4 server RR 4096 2 client RR 4096 2 client SR 1024 2 -f server SR 1024 2 -f
79 set ETIME=!DATE! !TIME!
80 goto xit
81 )
82
83 if "%T%" == "conn" (
84 rem Connectivity test - client sends one buffer with one 4KB segments, one time.
85 rem add '-d' for debug output.
86 echo Simple Connectivity test
87 set CMD=%DT% -T T -s %S% -D %D% -i 1 -t 1 -w 1 client SR 4096 server SR 4096
88 goto xcmd
89 )
90
91 if "%T%" == "trans" (
92 echo %T%: Transaction test - 8192 iterations, 1 thread, SR 4KB buffers
93 set CMD=%DT% -T T -s %S% -D %D% -i 8192 -t 1 -w 1 client SR 4096 server SR 4096
94 goto xcmd
95 )
96
97 if "%T%" == "transm" (
98 echo %T%: Multiple RW, RR, SR transactions, 4096 iterations
99 set CMD=%DT% -T T -P -t 1 -w 1 -i 4096 -s %S% -D %D% client RW 4096 1 server RW 2048 4 server RR 1024 2 client RR 2048 2 client SR 1024 3 -f server SR 256 3 -f
100 goto xcmd
101 )
102
103 if "%T%" == "transt" (
104 echo %T%: Threads[4] Transaction test - 4096 iterations, 1 thread, SR 4KB buffers
105 set CMD=%DT% -T T -s %S% -D %D% -i 4096 -t 4 -w 1 client SR 8192 3 server SR 8192 3
106 goto xcmd
107 )
108
109 if "%T%" == "transme" (
110 echo %T%: 1 Thread Endpoints[4] transactions [RW, RR, SR], 4096 iterations
111 set CMD=%DT% -T T -P -t 1 -w 4 -i 4096 -s %S% -D %D% client RW 4096 1 server RW 2048 4 server RR 1024 2 client RR 2048 2 client SR 1024 3 -f server SR 256 3 -f
112 goto xcmd
113 )
114
115 if "%T%" == "transmet" (
116 echo %T%: Threads[2] Endpoints[4] transactions[RW, RR, SR], 4096 iterations
117 set CMD=%DT% -T T -P -t 2 -w 4 -i 4096 -s %S% -D %D% client RW 4096 1 server RW 2048 4 server RR 1024 2 client RR 2048 2 client SR 1024 3 -f server SR 256 3 -f
118 goto xcmd
119 )
120
121 if "%T%" == "transmete" (
122 echo %T%: Threads[4] Endpoints[4] transactions[RW, RR, SR], 8192 iterations
123 set CMD=%DT% -T T -P -t 2 -w 4 -i 8192 -s %S% -D %D% client RW 4096 1 server RW 2048 4 server RR 1024 2 client RR 2048 2 client SR 1024 3 -f server SR 256 3 -f
124 goto xcmd
125 )
126
127 if "%T%" == "EPA" (
128 set STIME=!DATE! !TIME!
129 FOR /L %%j IN (2,1,5) DO (
130 FOR /L %%i IN (1,1,5) DO (
131 echo %T%: Multi: Threads[%%j] Endpoints[%%i] Send/Recv test - 4096 iterations, 3 8K segs
132 %DT% -T T -s %S% -D %D% -i 4096 -t %%j -w %%i client SR 8192 3 server SR 8192 3
133 if ERRORLEVEL 1 exit /B %ERRORLEVEL%
134 echo %T%: Multi: Threads[%%j] Endpoints[%%i] Send/Recv test - 4096 iterations, 3 8K segs
135 timeout /T 3
136 )
137 )
138 set ETIME=!DATE! !TIME!
139 goto xit
140 )
141
142 if "%T%" == "EP" (
143 set TH=4
144 set EP=3
145 echo %T%: Multi: Threads[!TH!] endpoints[!EP!] Send/Recv test - 4096 iterations, 3 8K segs
146 set CMD=%DT% -T T -s %S% -D %D% -i 4096 -t !TH! -w !EP! client SR 8192 3 server SR 8192 3
147 goto xcmd
148 )
149
150 if "%T%" == "threads" (
151 echo %T%: Multi Threaded[6] Send/Recv test - 4096 iterations, 3 8K segs
152 set CMD=%DT% -T T -s %S% -D %D% -i 4096 -t 6 -w 1 client SR 8192 3 server SR 8192 3
153 goto xcmd
154 )
155
156 if "%T%" == "threadsm" (
157 set TH=5
158 set EP=3
159 echo %T%: Multi: Threads[!TH!] endpoints[!EP!] Send/Recv test - 4096 iterations, 3 8K segs
160 set CMD=%DT% -T T -s %S% -D %D% -i 4096 -t !TH! -w !EP! client SR 8192 3 server SR 8192 3
161 goto xcmd
162 )
163
164 if "%T%" == "perf" (
165 rem echo Performance test
166 set CMD=%DT% -T P %DBG% -s %S% -D %D% -i 2048 RW 4096 2
167 goto xcmd
168 )
169
170 if "%T%" == "rdma-read" (
171 echo %T% 4 32K segs
172 set CMD=%DT% -T P -s %S% -D %D% -i 4096 RR 32768 4
173 goto xcmd
174 )
175
176 if "%T%" == "rdma-write" (
177 echo %T% 4 32K segs
178 set CMD=%DT% -T P -s %S% -D %D% -i 4096 RW 32768 4
179 goto xcmd
180 )
181
182 if "%T%" == "bw" (
183 echo bandwidth 4096 iterations of 2 65K mesgs
184 set CMD=%DT% -T P -s %S% -D %D% -i 4096 -p 16 -m p RW 65536 2
185 goto xcmd
186 )
187
188 if "%T%" == "latb" (
189 echo latency test - block for completion events
190 set CMD=%DT% -T P -s %S% -D %D% -i 8192 -p 1 -m b RW 4 1
191 goto xcmd
192 )
193
194 if "%T%" == "latp" (
195 echo latency test - poll completion events
196 set CMD=%DT% -T P -s %S% -D %D% -i 8192 -p 1 -m p RW 4 1
197 goto xcmd
198 )
199
200 if "%T%" == "lim" (
201 echo Resource limit tests
202 set STIME=!DATE! !TIME!
203 %DT% -T L -D %D% -w 8 -m 100 limit_ia
204 %DT% -T L -D %D% -w 8 -m 100 limit_pz
205 %DT% -T L -D %D% -w 8 -m 100 limit_evd
206 %DT% -T L -D %D% -w 8 -m 100 limit_ep
207 %DT% -T L -D %D% -w 8 -m 100 limit_psp
208 %DT% -T L -D %D% -w 8 -m 100 limit_lmr
209 %DT% -T L -D %D% -w 8 -m 15 limit_rpost
210 set ETIME=!DATE! !TIME!
211 goto xit
212 )
213
214 if "%T%" == "regression" (
215 rem run dapl regression tests - usage: dt-cli provider svr-IPaddr regression {loopCnt}
216 if "%X%" == "" (
217 if not "%4" == "" set LPS=%4
218 ) else (
219 if not "%5" == "" set LPS=%5
220 )
221 echo %T% testing in !LPS! Loops
222 REM rdma-write, read, perf
223 set RT=trans perf threads threadsm transm transt transme transmet transmete rdma-write rdma-read bw EP
224 set STIME=!DATE! !TIME!
225 FOR /L %%i IN (1,1,!LPS!) DO (
226 for %%r in ( !RT! ) do (
227 echo loop %%i - start test %%r
228 call %0 %1 %2 %%r
229 if !ERRORLEVEL! GTR 1 (
230 echo Error !ERRORLEVEL! in regression test %%r
231 exit /B !ERRORLEVEL!
232 )
233 echo loop %%i - Completed test %%r
234 if not "%%r" == "EP" timeout /T 3
235 )
236 echo +
237 echo Finished %T% loop %%i of !LPS!
238 if %%i LSS !LPS! timeout /T 8
239 )
240 set ETIME=!DATE! !TIME!
241 goto xit
242 )
243
244 if "%T%" == "interop" (
245 REM test units from Nov-'07 OFA interop event. usage dt-cli server-IPaddr interop {LoopCount}
246 if "%X%" == "" (
247 if not "%4" == "" set LPS=%4
248 ) else (
249 if not "%5" == "" set LPS=%5
250 )
251 echo %T% testing in !LPS! Loops
252 REM test units from Nov-'07 OFA interop event
253 set STIME=!DATE! !TIME!
254 FOR /L %%i IN (1,1,!LPS!) DO (
255 echo %DT% -T T -s %S% -D %D% -i 4096 -t 1 -w 1 -R BE client SR 256 1 server SR 256 1
256 %DT% -T T -s %S% -D %D% -i 4096 -t 1 -w 1 -R BE client SR 256 1 server SR 256 1
257 if ERRORLEVEL 1 exit /B %ERRORLEVEL%
258 timeout /T 3
259 echo %DT% -T T -s %S% -D %D% -i 100 -t 1 -w 1 -V -P -R BE client SR 1024 3 -f server SR 1536 2 -f
260 %DT% -T T -s %S% -D %D% -i 100 -t 1 -w 1 -V -P -R BE client SR 1024 3 -f server SR 1536 2 -f
261 if ERRORLEVEL 1 exit /B %ERRORLEVEL%
262 timeout /T 3
263 echo %DT% -T T -s %S% -D %D% -i 100 -t 1 -w 1 -V -P -R BE client SR 1024 1 server SR 1024 1
264 %DT% -T T -s %S% -D %D% -i 100 -t 1 -w 1 -V -P -R BE client SR 1024 1 server SR 1024 1
265 if ERRORLEVEL 1 exit /B %ERRORLEVEL%
266 timeout /T 3
267 echo %DT% -T T -s %S% -D %D% -i 100 -t 1 -w 10 -V -P -R BE client SR 1024 3 server SR 1536 2
268 %DT% -T T -s %S% -D %D% -i 100 -t 1 -w 10 -V -P -R BE client SR 1024 3 server SR 1536 2
269 if ERRORLEVEL 1 exit /B %ERRORLEVEL%
270 timeout /T 3
271 echo %DT% -T T -s %S% -D %D% -i 100 -t 1 -w 1 -V -P -R BE client SR 256 1 server RW 4096 1 server SR 256 1
272 %DT% -T T -s %S% -D %D% -i 100 -t 1 -w 1 -V -P -R BE client SR 256 1 server RW 4096 1 server SR 256 1
273 if ERRORLEVEL 1 exit /B %ERRORLEVEL%
274 timeout /T 3
275 echo %DT% -T T -s %S% -D %D% -i 100 -t 1 -w 1 -V -P -R BE client SR 256 1 server RR 4096 1 server SR 256 1
276 %DT% -T T -s %S% -D %D% -i 100 -t 1 -w 1 -V -P -R BE client SR 256 1 server RR 4096 1 server SR 256 1
277 if ERRORLEVEL 1 exit /B %ERRORLEVEL%
278 timeout /T 3
279 echo %DT% -T T -s %S% -D %D% -i 100 -t 4 -w 8 -V -P -R BE client SR 256 1 server RR 4096 1 server SR 256 1 client SR 256 1 server RR 4096 1 server SR 256 1
280 %DT% -T T -s %S% -D %D% -i 100 -t 4 -w 8 -V -P -R BE client SR 256 1 server RR 4096 1 server SR 256 1 client SR 256 1 server RR 4096 1 server SR 256 1
281 if ERRORLEVEL 1 exit /B %ERRORLEVEL%
282 timeout /T 3
283 echo %DT% -T P -s %S% -D %D% -i 1024 -p 64 -m p RW 8192 2
284 %DT% -T P -s %S% -D %D% -i 1024 -p 64 -m p RW 8192 2
285 if ERRORLEVEL 1 exit /B %ERRORLEVEL%
286 timeout /T 3
287 echo %DT% -T P -s %S% -D %D% -i 1024 -p 64 -m p RW 4096 2
288 %DT% -T P -s %S% -D %D% -i 1024 -p 64 -m p RW 4096 2
289 if ERRORLEVEL 1 exit /B %ERRORLEVEL%
290 timeout /T 3
291 echo %DT% -T P -s %S% -D %D% -i 1024 -p 64 -m p RW 4096 1
292 %DT% -T P -s %S% -D %D% -i 1024 -p 64 -m p RW 4096 1
293 if ERRORLEVEL 1 exit /B %ERRORLEVEL%
294 timeout /T 3
295 echo %DT% -T T -s %S% -D %D% -i 100 -t 1 -w 10 -V -P -R BE client SR 1024 3 server SR 1536 2
296 %DT% -T T -s %S% -D %D% -i 100 -t 1 -w 10 -V -P -R BE client SR 1024 3 server SR 1536 2
297 if ERRORLEVEL 1 exit /B %ERRORLEVEL%
298 echo %%i %T% loops of !LPS! completed.
299 if %%i LSS !LPS! timeout /T 8
300 )
301 set ETIME=!DATE! !TIME!
302 goto xit
303 )
304
305 if "%T%" == "stop" (
306 %DT% -T Q -s %S% -D %D%
307 goto rxt
308 )
309
310 :usage
311
312 echo.
313 echo usage: dt-cli dapl-provider dt-svr-hostname [testname [-D]]
314 echo.
315 echo where:
316 echo.
317 echo dapl-provider: ibal, scm, cma or %SystemDrive%\DAT\dat.conf DAPL-provider name.
318 echo.
319 echo dt-svr-hostname - IPv4 hostanme where the DaplTest server is running
320 echo.
321 echo testname
322 echo stop - request DAPLtest server to exit.
323 echo conn - simple connection test with limited data transfer
324 echo EP - Multiple EndPoints(7) and Threads(5) Transactions
325 echo EPA - Increment EndPoints[1..5] while increasing threads[1-5]
326 echo trans - single transaction test
327 echo transm - transaction test: multiple transactions [RW SND, RDMA]
328 echo transt - transaction test: multi-threaded
329 echo transme - transaction test: multi-endpoints per thread
330 echo transmet - transaction test: multi-endpoints per thread, multiple threads
331 echo transmete - transaction test: multi threads == endpoints
332 echo perf - Performance test
333 echo threads - multi-threaded single transaction test.
334 echo threadsm - multi: threads and endpoints, single transaction test.
335 echo rdma-write - RDMA write
336 echo rdma-read - RDMA read
337 echo bw - bandwidth
338 echo latb - latency tests, blocking for events
339 echo latp - latency tests, polling for events
340 echo lim - limit tests.
341 echo regression {loopCnt,default=%LPS%} - regression + stress.
342 echo interop {loopCnt,default=%LPS%} - 2007 OFA interoperability event tests.
343 goto rxt
344
345 rem Execute the single daplest Command (CMD), observe -Q switch
346 :xcmd
347 set STIME=!DATE! !TIME!
348 if %QUIET% EQU 1 (
349 %CMD% > nul
350 ) else (
351 %CMD%
352 )
353 set ETIME=!DATE! !TIME!
354
355 rem fall thru...
356
357 :xit
358
359 if !ERRORLEVEL! EQU 0 (
360 echo.
361 echo %0 %*
362 echo Start %STIME%
363 echo End %ETIME%
364 )
365 :rxt
366 ENDLOCAL
367 exit /B !ERRORLEVEL!