Debian Codegraph @

test/regress/cli/regress0/strings/from_code.smt2

raw
1 ; COMMAND-LINE: --lang=smt2.6
2 ; EXPECT: unsat
3 ; EXPECT: unsat
4 ; EXPECT: sat
5 ; EXPECT: unsat
6 ; EXPECT: sat
7 ; EXPECT: unsat
8 ; EXPECT: sat
9 ; EXPECT: unsat
10 ; EXPECT: unsat
11 (set-option :incremental true)
12 (set-logic QF_SLIA)
13 (declare-const s String)
14 (declare-const t String)
15 (declare-const n Int)
16
17 (push)
18 (assert (not (= (str.to_code (str.from_code (str.to_code s))) (str.to_code s))))
19 (check-sat)
20 (pop)
21
22 (push)
23 (assert (not (= (str.from_code (str.to_code s)) s)))
24 (assert (<= (str.len s) 1))
25 (check-sat)
26 (pop)
27
28 (push)
29 (assert (not (= (str.from_code (str.to_code s)) s)))
30 (check-sat)
31 (pop)
32
33 (push)
34 (assert (not (= (str.from_code (str.to_code (str.from_code n))) (str.from_code n))))
35 (check-sat)
36 (pop)
37
38 (push)
39 (assert (not (= (str.to_code (str.from_code n)) n)))
40 (assert (>= n 0))
41 (check-sat)
42 (pop)
43
44 (push)
45 (assert (not (= (str.to_code (str.from_code n)) n)))
46 (assert (and (>= n 0) (< n 50)))
47 (check-sat)
48 (pop)
49
50 (push)
51 (assert (not (= (str.to_code (str.from_code n)) n)))
52 (check-sat)
53 (pop)
54
55 (push)
56 (assert (= (str.to_code s) (str.to_code t)))
57 (assert (= (str.len s) 1))
58 (assert (= (str.len t) 1))
59 (assert (not (= (str.from_code (str.to_code s)) (str.from_code (str.to_code t)))))
60 (check-sat)
61 (pop)
62
63 (push)
64 (assert (or
65 (not (= (str.from_code (- 1)) ""))
66 (not (= (str.from_code 100000000000000000000000) ""))
67 (not (= (str.from_code 65) "A"))))
68 (check-sat)
69 (pop)