Debian Codegraph @

source/util/mac-crawl-build-update-cdo

raw
1 #! /usr/bin/env perl
2 #
3 # Runs the Mac Crawl tiles and ASCII builds and uploads them to CDO. Needs
4 # to be run as a user with a suitable ssh key for CDO.
5 #
6 # WARNING: Will do git clean -fdx in the current tree automatically;
7 # don't run this in a tree you're using for real work.
8
9 use strict;
10 use warnings;
11
12 use Cwd;
13 use Getopt::Long;
14
15 my $CRAWLDIR;
16
17 $ENV{PATH} = "$ENV{PATH}:/opt/local/bin";
18 my $LASTVERFILE = "crawl-ref/last-mac-build.version";
19
20 my $COMPILEDIR = "crawl-ref/source";
21 my $ZIPDIR = "$COMPILEDIR/mac-app-zips";
22 my $BUILDDIR = "crawl-ref/source";
23 my @APPS = ("Dungeon Crawl Stone Soup.app",
24 "Dungeon Crawl Stone Soup - ASCII.app");
25 my $ZIPNAMEFMT = 'crawl_%sosx-%s.zip';
26 my $REMOTE_HOST = '[email protected]';
27 my $SCP_PATH = "$REMOTE_HOST:/var/www/crawl.develz.org/htdocs/trunk";
28 my $CURRENTVERSION;
29
30 my $SKIP_BUILD;
31 my $SCP;
32 GetOptions("skip-build" => \$SKIP_BUILD,
33 "scp" => \$SCP)
34 or die "Bad command line\n";
35
36 sub main()
37 {
38 $CRAWLDIR = discover_crawl_dir();
39 goto_dir($CRAWLDIR);
40
41 my $last_build_version = last_build_version();
42 update_git();
43 $CURRENTVERSION = current_version();
44
45 my $need_build =
46 !$last_build_version || $last_build_version ne $CURRENTVERSION;
47
48 my $did_build;
49 my $did_scp;
50 if ($need_build)
51 {
52 if (!$SKIP_BUILD)
53 {
54 if ($last_build_version)
55 {
56 say("[INFO] Last build: $last_build_version; current: $CURRENTVERSION");
57 }
58 else
59 {
60 say("[INFO] Current version: $CURRENTVERSION");
61 }
62 build_crawl();
63 $did_build = 1;
64 package_build();
65 save_build_version($CURRENTVERSION);
66 }
67 }
68
69 if ($need_build || $SCP)
70 {
71 my @binaries = find_uploadable_binaries();
72 print("Zips: @binaries\n");
73 upload_binaries(@binaries);
74 $did_scp = 1;
75 }
76
77 if (!$did_build && !$did_scp)
78 {
79 if (!$need_build)
80 {
81 say("[INFO] $CURRENTVERSION already built, nothing to do");
82 }
83 else
84 {
85 say("[INFO] Nothing to do");
86 }
87 }
88 }
89
90 sub directory_has_paths(@)
91 {
92 my @paths = @_;
93 for my $path (@paths)
94 {
95 my $dir = $path =~ s{/$}{};
96 return undef unless ($dir? -d($path) : -r($path));
97 }
98 1
99 }
100
101 sub find_parent_directory_containing($@)
102 {
103 my ($failmsg, @paths) = @_;
104 my $current_dir = getcwd();
105 while (1)
106 {
107 return $current_dir if directory_has_paths(@paths);
108
109 chdir("..") or die "$failmsg\n";
110 my $parent = getcwd();
111 die "$failmsg\n" if $parent eq $current_dir;
112 $current_dir = $parent;
113 }
114 }
115
116 sub discover_crawl_dir()
117 {
118 find_parent_directory_containing(
119 "[ERR] Couldn't find crawl-ref repository top-level directory",
120 ".git/", "crawl-ref/git-hooks/",
121 "crawl-ref/source/", "crawl-ref/source/rltiles/")
122 }
123
124 sub last_build_version()
125 {
126 open my $inf, '<', $LASTVERFILE or return;
127 chomp(my $lastver = <$inf>);
128 close $inf;
129 $lastver
130 }
131
132 sub save_build_version($)
133 {
134 my $version = shift;
135 open my $outf, '>', $LASTVERFILE or die "Can't write $LASTVERFILE: $!\n";
136 print $outf "$version\n";
137 close $outf;
138 }
139
140 sub say($)
141 {
142 my $msg = shift;
143 warn("$msg\n") if -t STDIN;
144 }
145
146 sub clean_crawl()
147 {
148 sys_check("git clean -dfx");
149 }
150
151 sub in_dir($$)
152 {
153 my ($dir, $task) = @_;
154 my $start_dir = getcwd();
155 goto_dir($dir);
156 eval { $task->(); };
157 my $err = $@;
158 goto_dir($start_dir);
159 die $err if $err;
160 }
161
162 sub build_crawl()
163 {
164 clean_crawl();
165 in_dir($COMPILEDIR,
166 sub
167 {
168 sys_check("./mac/mac-release-build");
169 });
170 }
171
172 sub app_zips()
173 {
174 my $zipglob = "$ZIPDIR/stone_soup-$CURRENTVERSION*.zip";
175 return glob($zipglob);
176 }
177
178 sub assert_app_zips_exist()
179 {
180 my @zips = app_zips();
181 @zips == 2 or die "[ERR] Zip files not built as expected\n";
182 }
183
184 sub zip_name_for_app($)
185 {
186 my $app = shift;
187 my $tiles = $app !~ /ASCII/;
188 my $qualifier = $tiles ? "tiles_" : "";
189 sprintf($ZIPNAMEFMT, $qualifier, $CURRENTVERSION)
190 }
191
192 sub create_app_zips()
193 {
194 my @zips = app_zips();
195 my @out_zips = ();
196 for my $zip (@zips)
197 {
198 my $target =
199 "$ZIPDIR/" . zip_name_for_app($zip =~ /tiles/? 'TILES' : 'ASCII');
200 rename($zip, $target);
201 push @out_zips, $target;
202 }
203 @out_zips
204 }
205
206 sub package_build()
207 {
208 assert_app_zips_exist();
209 return create_app_zips();
210 }
211
212 sub find_uploadable_binaries()
213 {
214 my $zipglob = sprintf("$ZIPDIR/$ZIPNAMEFMT", "*", "*");
215 my @zips = glob($zipglob);
216 @zips == 2 or die "[ERR] Can't find zips to upload: $zipglob\n";
217 @zips
218 }
219
220 sub scp($$)
221 {
222 my ($src, $targ) = @_;
223 sys_check("scp $src $targ");
224 }
225
226 sub upload_binary($)
227 {
228 my $zip = shift;
229 scp($zip, $SCP_PATH);
230 }
231
232 sub update_trunk_page()
233 {
234 sys_check("ssh $REMOTE_HOST bin/update-trunk-indices.py");
235 }
236
237 sub upload_binaries(@)
238 {
239 my @zips = @_;
240 for my $zip (@zips)
241 {
242 die "[ERR] Zip $zip does not exist\n" unless -f $zip;
243 upload_binary($zip);
244 }
245 update_trunk_page();
246 }
247
248 sub current_version()
249 {
250 chomp(my $ver = qx/git describe --long/);
251 die "[ERR] git describe failed\n" if ($? >> 8) || !$ver;
252 $ver
253 }
254
255 sub goto_dir($)
256 {
257 my $dir = shift;
258 say("[CD] $dir");
259 chdir($dir) or die "Can't chdir to $dir: $!\n";
260 }
261
262 sub retry_until_success($$$)
263 {
264 my ($tries, $desc, $task) = @_;
265
266 while ($tries-- > 0)
267 {
268 last if $task->();
269 }
270 die "ERR: $desc failed\n" if $tries < 0;
271 }
272
273 sub sys_retry_until_success($$)
274 {
275 my ($tries, $command) = @_;
276 my $task = sub { !sys_do($command) };
277 retry_until_success($tries, $command, $task);
278 }
279
280 sub sys_do($)
281 {
282 my $command = shift;
283 say("[SYSTEM] $command");
284 system($command)
285 }
286
287 sub sys_check($)
288 {
289 my $command = shift;
290 !sys_do($command) or die "[ERR] $command failed\n";
291 }
292
293 sub update_git()
294 {
295 sys_retry_until_success(200, "git pull");
296 sys_retry_until_success(200, "git submodule update --init");
297 }
298
299 main();