Debian Codegraph @

Release/cmake/cpprest_find_openssl.cmake

raw
1 function(cpprest_find_openssl)
2 if(TARGET cpprestsdk_openssl_internal)
3 return()
4 endif()
5
6 if(IOS)
7 set(IOS_SOURCE_DIR "${PROJECT_SOURCE_DIR}/../Build_iOS")
8
9 set(OPENSSL_INCLUDE_DIR "${IOS_SOURCE_DIR}/openssl/include" CACHE INTERNAL "")
10 set(OPENSSL_LIBRARIES
11 "${IOS_SOURCE_DIR}/openssl/lib/libcrypto.a"
12 "${IOS_SOURCE_DIR}/openssl/lib/libssl.a"
13 CACHE INTERNAL ""
14 )
15 set(_SSL_LEAK_SUPPRESS_AVAILABLE ON CACHE INTERNAL "")
16 elseif(ANDROID)
17 if(ARM)
18 set(OPENSSL_INCLUDE_DIR "${CMAKE_BINARY_DIR}/../openssl/armeabi-v7a/include" CACHE INTERNAL "")
19 set(OPENSSL_LIBRARIES
20 "${CMAKE_BINARY_DIR}/../openssl/armeabi-v7a/lib/libssl.a"
21 "${CMAKE_BINARY_DIR}/../openssl/armeabi-v7a/lib/libcrypto.a"
22 CACHE INTERNAL ""
23 )
24 else()
25 set(OPENSSL_INCLUDE_DIR "${CMAKE_BINARY_DIR}/../openssl/x86/include" CACHE INTERNAL "")
26 set(OPENSSL_LIBRARIES
27 "${CMAKE_BINARY_DIR}/../openssl/x86/lib/libssl.a"
28 "${CMAKE_BINARY_DIR}/../openssl/x86/lib/libcrypto.a"
29 CACHE INTERNAL ""
30 )
31 endif()
32 set(_SSL_LEAK_SUPPRESS_AVAILABLE ON CACHE INTERNAL "")
33 else()
34 if(APPLE)
35 if(NOT DEFINED OPENSSL_ROOT_DIR)
36 # Prefer a homebrew version of OpenSSL over the one in /usr/lib
37 file(GLOB OPENSSL_ROOT_DIR /usr/local/Cellar/openssl*/*)
38 # Prefer the latest (make the latest one first)
39 list(REVERSE OPENSSL_ROOT_DIR)
40 list(GET OPENSSL_ROOT_DIR 0 OPENSSL_ROOT_DIR)
41 endif()
42 # This should prevent linking against the system provided 0.9.8y
43 message(STATUS "OPENSSL_ROOT_DIR = ${OPENSSL_ROOT_DIR}")
44 set(_OPENSSL_VERSION "")
45 endif()
46 if(UNIX)
47 find_package(PkgConfig)
48 pkg_search_module(OPENSSL openssl)
49 endif()
50 if(OPENSSL_FOUND)
51 target_link_libraries(cpprest PRIVATE ${OPENSSL_LDFLAGS})
52 else()
53 find_package(OpenSSL 1.0.0 REQUIRED)
54 endif()
55
56 INCLUDE(CheckCXXSourceCompiles)
57 set(CMAKE_REQUIRED_INCLUDES "${OPENSSL_INCLUDE_DIR}")
58 set(CMAKE_REQUIRED_LIBRARIES "${OPENSSL_LIBRARIES}")
59 CHECK_CXX_SOURCE_COMPILES("
60 #include <openssl/ssl.h>
61 int main()
62 {
63 ::SSL_COMP_free_compression_methods();
64 }
65 " _SSL_LEAK_SUPPRESS_AVAILABLE)
66 endif()
67
68 add_library(cpprestsdk_openssl_internal INTERFACE)
69 if(TARGET OpenSSL::SSL)
70 target_link_libraries(cpprestsdk_openssl_internal INTERFACE OpenSSL::SSL)
71 else()
72 target_link_libraries(cpprestsdk_openssl_internal INTERFACE "$<BUILD_INTERFACE:${OPENSSL_LIBRARIES}>")
73 target_include_directories(cpprestsdk_openssl_internal INTERFACE "$<BUILD_INTERFACE:${OPENSSL_INCLUDE_DIR}>")
74 endif()
75
76 if (NOT _SSL_LEAK_SUPPRESS_AVAILABLE)
77 # libressl doesn't ship with the cleanup method being used in ws_client_wspp
78 target_compile_definitions(cpprestsdk_openssl_internal INTERFACE -DCPPREST_NO_SSL_LEAK_SUPPRESS)
79 endif()
80 endfunction()