Debian Codegraph @

src/platform/mac/copyqpasteboardmime.mm

raw
1 // SPDX-License-Identifier: GPL-3.0-or-later
2
3 #include "copyqpasteboardmime.h"
4 #include "cfref.h"
5
6 #include "common/log.h"
7 #include "common/mimetypes.h"
8
9 #include <QClipboard>
10 #include <QEvent>
11 #include <QVariant>
12
13 #import <CoreServices/CoreServices.h>
14
15 namespace {
16 // MIME prefix used by other Qt apps to handle unknown mime types
17 const QString QT_UTI_PREFIX("com.trolltech.anymime.");
18
19 // types handled by other (builtin) converters
20 bool shouldIgnoreUTI(const QString &uti) {
21 return uti == QLatin1String("public.html")
22 || uti == QLatin1String("public.url")
23 || uti == QLatin1String("public.file-url")
24 || uti == QLatin1String("public.utf8-plain-text")
25 || uti == QLatin1String("public.utf16-plain-text")
26 || uti == QLatin1String("public.utf16-external-plain-text")
27 || uti == QLatin1String("com.apple.traditional-mac-plain-text");
28 }
29
30 // types handled by other (builtin) converters
31 bool shouldIgnoreMime(const QString &mime) {
32 return mime == QLatin1String("application/x-qt-image")
33 || mime == QLatin1String("text/html")
34 || mime == QLatin1String("text/plain")
35 || mime == QLatin1String("text/uri-list")
36 || mime == QLatin1String("application/x-copyq-owner-window-title");
37 }
38
39 CFStringRef mimeToUTI(CFStringRef mime) {
40 return UTTypeCreatePreferredIdentifierForTag(kUTTagClassMIMEType, mime, NULL);
41 }
42
43 CFStringRef utiToMime(CFStringRef uti) {
44 return UTTypeCopyPreferredTagWithClass((__bridge CFStringRef)uti, kUTTagClassMIMEType);
45 }
46
47 QString convertUtiOrMime(const QString &in, CFStringRef (*convert)(CFStringRef)) {
48 NSString *inString = in.toNSString();
49 CFRef<CFStringRef> outRef = convert((__bridge CFStringRef)inString);
50 QString out;
51 if (outRef)
52 out = QString::fromNSString((__bridge NSString *)outRef.get());
53 return out;
54 }
55
56 }
57
58 QString CopyQPasteboardMime::utiForMime(const QString &mime) const
59 {
60 if (shouldIgnoreMime(mime)) {
61 return QString();
62 }
63
64 QString uti = convertUtiOrMime(mime, mimeToUTI);
65 if (!uti.isEmpty()) {
66 return uti;
67 }
68
69 if (mime.startsWith(COPYQ_MIME_PREFIX)) {
70 return mime.mid(QLatin1String(COPYQ_MIME_PREFIX).size());
71 }
72
73 return QString();
74 }
75
76 QString CopyQPasteboardMime::mimeForUti(const QString &uti) const
77 {
78 if (shouldIgnoreUTI(uti)) {
79 return QString();
80 }
81
82 // Handle mime data that Qt has converted by force to UTI
83 if (uti.startsWith(QT_UTI_PREFIX)) {
84 return uti.mid(QT_UTI_PREFIX.length()).replace("--", "/");
85 }
86
87 QString mime = convertUtiOrMime(uti, utiToMime);
88 if (!mime.isEmpty()) {
89 return mime;
90 }
91
92 return COPYQ_MIME_PREFIX + uti;
93 }
94
95
96 QVariant CopyQPasteboardMime::convertToMime(const QString &mime, const QList<QByteArray> &data, const QString &uti) const
97 {
98 if (!canConvert(mime, uti)) {
99 return QVariant();
100 }
101
102 if (data.count() == 1) {
103 return QVariant::fromValue(data[0]);
104 } else {
105 QVariantList ret;
106 foreach(const QByteArray &item, data) {
107 ret << QVariant::fromValue(item);
108 }
109 return ret;
110 }
111 }
112
113 QList<QByteArray> CopyQPasteboardMime::convertFromMime(const QString &mime, const QVariant &data, const QString &uti) const
114 {
115 if (!canConvert(mime, uti)) {
116 return QList<QByteArray>();
117 }
118
119 QList<QByteArray> ret;
120 if (data.userType() == QMetaType::QByteArray) {
121 // Was a single item
122 ret << data.toByteArray();
123 } else {
124 // Was a list or null
125 QVariantList inp = data.toList();
126 foreach(const QVariant &item, inp) {
127 ret << item.toByteArray();
128 }
129 }
130 return ret;
131 }