Debian Codegraph @

tools/spgen/source/script_rule.ml

raw
1 (*
2 * This file is part of Coccinelle, lincensed under the terms of the GPL v2.
3 * See copyright.txt in the Coccinelle source code for more information.
4 * The Coccinelle source code can be obtained at http://coccinelle.lip6.fr
5 *)
6
7 module MV = Meta_variable
8 module UI = User_input
9
10 (* ------------------------------------------------------------------------- *)
11
12 (* Generate script rules for org and report. *)
13
14 (* ------------------------------------------------------------------------- *)
15 (* TYPES AND HELPERS *)
16
17 type t = string list (*org*) * string list (*rep*)
18
19 let comma_sep = String.concat ","
20
21 (* invariant: always at least one position *)
22 let split_pos = function mv::mvs -> (mv,mvs) | _ -> assert false
23
24 (* print helpers for script rules (which are really just string lists) *)
25 let print_newl out = output_string out "\n"
26 let printfn out x =
27 List.iter (fun x -> output_string out x; print_newl out) x;
28 print_newl out
29
30 (* remove period at the end of the message if there is one (prevent doubles) *)
31 let remove_period msg =
32 let len_but_one = String.length msg - 1 in
33 let last = msg.[len_but_one] in
34 if last = '.' then String.sub msg 0 len_but_one else msg
35
36 (* ------------------------------------------------------------------------- *)
37 (* CONSTANTS *)
38
39 let print_todo_fn = "coccilib.org.print_todo"
40 let print_safe_todo_fn = "coccilib.org.print_safe_todo"
41 let print_link_fn = "coccilib.org.print_link"
42 let print_report_fn = "coccilib.report.print_report"
43
44
45 (* ------------------------------------------------------------------------- *)
46 (* SCRIPT GENERATION FUNCTIONS *)
47
48 (* Format the variables used in the format string.
49 * Returns ("around lines" string for metapos's, comma-separated mv names)
50 *)
51 let line_vars ~meta_pos ~meta_vars =
52 let line = List.map (fun x -> x ^ "[0].line") in
53 match meta_pos with
54 | [] -> ("", comma_sep meta_vars)
55 | [x] -> ("around line %s.", comma_sep (meta_vars @ (line [x])))
56 | x -> let agg = comma_sep (List.map (fun _ -> "%s") x) in
57 ("around lines " ^ agg ^ ".", comma_sep (meta_vars @ (line x)))
58
59 (* turn metavariables into script header variables *)
60 let format_header_vars =
61 let binding mv =
62 let (rn,nm) = (MV.get_rule mv, MV.get_name mv) in
63 nm ^ " << " ^ rn ^ "." ^ nm ^ ";" in
64 List.map binding
65
66 (* only include metavars/positions in the format string if more than one *)
67 let format_err_msg err_msg mpnames mvnames =
68 if (List.length mvnames + List.length mpnames) > 0 then
69 let (linepos, formatvars) =
70 line_vars ~meta_pos:mpnames ~meta_vars:mvnames in
71 "msg = \"" ^ err_msg ^ " " ^ linepos ^ "\" % (" ^ formatvars ^ ")"
72 else
73 "msg = \"" ^ err_msg ^ ".\""
74
75 (* assembles an org script rule. *)
76 let gen_org_rule nm (firstpos, restpos) metavars err_msg =
77
78 (* if there are metavars, they might contain brackets which conflict with
79 * the todo format. In that case, use safe mode (replaces brackets).
80 *)
81 let printfn = if metavars <> [] then print_safe_todo_fn else print_todo_fn in
82 let new_rulenm = Globals.get_org_name nm in
83 let headervars = format_header_vars (metavars @ (firstpos :: restpos)) in
84 (* the error message is used as is, positions are inserted in print calls *)
85 let metavars = List.map MV.get_name metavars in
86 let err_msg = format_err_msg err_msg [] metavars in
87 let zero p = (MV.get_name p) ^ "[0]" in
88 [
89 (*header*)
90 Globals.concat_limit_width
91 ["@script:python "; new_rulenm; " depends on org@"];
92 String.concat "\n" headervars;
93 "@@\n";
94 (*body*)
95 err_msg;
96 (printfn ^ "(" ^ (zero firstpos) ^ ", msg)")
97 ] @ (List.map (fun x -> print_link_fn ^ "(" ^ (zero x) ^ ", \"\")") restpos)
98
99 (* assembles a report script rule. *)
100 let gen_report_rule nm (firstpos, restpos) metavars err_msg =
101 let new_rulenm = Globals.get_report_name nm in
102 let headervars = format_header_vars (metavars @ (firstpos :: restpos)) in
103 let firstpos = (MV.get_name (firstpos)) ^ "[0]" in
104 let restpos = List.map MV.get_name restpos in
105 let metavars = List.map MV.get_name metavars in
106 let err_msg = format_err_msg err_msg restpos metavars in
107 [
108 (*header*)
109 Globals.concat_limit_width
110 ["@script:python "; new_rulenm; " depends on report@"];
111 String.concat "\n" headervars;
112 "@@\n";
113 (*body*)
114 err_msg;
115 (print_report_fn ^ "(" ^ firstpos ^ ", msg)")
116 ]
117
118
119 (* ------------------------------------------------------------------------- *)
120 (* ENTRY POINT *)
121
122 (* generate org and report rule for the added metapositions and with the user
123 * specified information (error messages).
124 *)
125 let generate ~meta_pos ~user_rule =
126
127 (* extract user-specified data from rule *)
128 let nm = UI.Rule.get_name user_rule in
129 let org_msg, omv = UI.Rule.get_org user_rule in
130 let report_msg, rmv = UI.Rule.get_report user_rule in
131 let org_msg, report_msg = remove_period org_msg, remove_period report_msg in
132
133 (* find the first position, fails if the meta_pos list is empty *)
134 let firstpos, restpos = split_pos meta_pos in
135 let new_rule = MV.get_rule firstpos in
136
137 (* make sure user-specified metavars are inherited from the context rule *)
138 let omv = List.map (MV.inherit_rule ~new_rule) omv in
139 let rmv = List.map (MV.inherit_rule ~new_rule) rmv in
140
141 (* generate org and report script rules *)
142 let org = gen_org_rule nm (firstpos, restpos) omv org_msg in
143 let report = gen_report_rule nm (firstpos, restpos) rmv report_msg in
144 org, report
145
146 let print_org out (org, _) = printfn out org
147
148 let print_report out (_, rep) = printfn out rep