Debian Codegraph @

build_tooling/cmake/tangent/codestyle.cmake

raw
1 # Create format and lint rules for a file manifest
2 #
3 # usage:
4 # ~~~
5 # format_and_lint(<slug>
6 # <file-list>
7 # [BZL <bzl-file-list>]
8 # [CMAKE <cmake-file-list>]
9 # [CC <cc-file-list>]
10 # [JS <js-file-list>]
11 # [PY <py-file-list>]
12 # [SHELL <sh-file-list>])
13 # ~~~
14 #
15 # Will create rules `${slug}_lint` and `${slug}_format` using the standard code
16 # formatters and lint checkers for the appropriate language. These tools are:
17 #
18 # ~~~
19 # BZL:
20 # formatter: buildifier
21 #
22 # CMAKE:
23 # formatter: cmake-format
24 # linter: cmake-lint
25 #
26 # CC:
27 # formatter: clang-format
28 # linter: cpplint, clang-tidy
29 #
30 # JS:
31 # formatter: js-beautify
32 # linter: eslint
33 #
34 # PY:
35 # formatter: autopep8
36 # linter: pylint, flake8
37 # ~~~
38 if(EXISTS ${CMAKE_SOURCE_DIR}/cmakelang)
39 set(CMAKE_FORMAT_CMD python -Bm cmakelang.format)
40 set(CMAKE_LINT_CMD python -Bm cmakelang.lint)
41 else()
42 set(CMAKE_FORMAT_CMD cmake-format)
43 set(CMAKE_LINT_CMD cmake-lint)
44 endif()
45
46 # TODO(josh): need to build this dynamically over the course of the
47 # configure-time, and then build the format and lint commands after we
48 # know all of the python path that needs to be included
49 set(_pythonpath "${CMAKE_SOURCE_DIR}:${CMAKE_BINARY_DIR}/pynix")
50
51 # Generate targets to format or lint the list of files
52 #
53 # Usage:
54 # ~~~
55 # format_and_lint(<slug>
56 # [BZL filepath1 [filepath2 [...]]]
57 # [CMAKE filepath1 [filepath2 [...]]]
58 # [CC filepath1 [filepath2 [...]]]
59 # [CCDEPENDS filepath1 [filepath2 [...]]]
60 # [JS filepath1 [filepath2 [...]]]
61 # [PY filepath1 [filepath2 [...]]]
62 # [SHELL filepath1 [filepath2 [...]]]
63 # )
64 # ~~~
65 function(format_and_lint slug)
66 # cmake-lint: disable=R0912,R0915
67 set(multiargs
68 BZL
69 CMAKE
70 CC
71 CCDEPENDS
72 JS
73 PY
74 SHELL)
75 cmake_parse_arguments(_args "" "" "${multiargs}" ${ARGN})
76 set(unknown_files)
77 foreach(arg ${_args_UNPARSED_ARGUMENTS})
78 if("${arg}" MATCHES ".*\\.bzl$"
79 OR "${arg}" MATCHES "(.*/)?BUILD"
80 OR "${arg}" MATCHES "(.*/)?WORKSPACE")
81 list(APPEND _args_BZL ${arg})
82 elseif("${arg}" MATCHES ".*\\.cmake$" OR "${arg}" MATCHES
83 ".*CMakeLists.txt")
84 list(APPEND _args_CMAKE ${arg})
85 elseif("${arg}" MATCHES ".*\\.py$")
86 list(APPEND _args_PY ${arg})
87 elseif("${arg}" MATCHES ".*\\.(h|(hh)|(hpp))$")
88 list(APPEND _args_CC ${arg})
89 elseif("${arg}" MATCHES ".*\\.tcc$")
90 list(APPEND _args_CC ${arg})
91 elseif("${arg}" MATCHES ".*\\.(c|(cc)|(cpp))$")
92 list(APPEND _args_CC ${arg})
93 elseif("${arg}" MATCHES ".*\\.js(\\.tpl)?$")
94 list(APPEND _args_JS ${arg})
95 elseif("${arg}" MATCHES ".*\\.sh$")
96 list(APPEND _args_SHELL ${arg})
97 else()
98 list(APPEND unknown_files ${arg})
99 endif()
100 endforeach()
101
102 # NOTE(josh): we create this dummy target which touches a dummy file that all
103 # the rules below depend on. This gives us a synchronization point where we
104 # can add dependencies and ensure these dependencies happen before any of the
105 # rules below.
106 set(lintdep_witness ${CMAKE_CURRENT_BINARY_DIR}/lint-${slug}-deps.witness)
107 add_custom_target(
108 lint-${slug}-deps
109 COMMAND touch -a ${lintdep_witness}
110 BYPRODUCTS ${lintdep_witness}
111 COMMENT "Dependency fence for lint-${slug}")
112
113 if(NOT CMAKE_GENERATOR STREQUAL "Ninja")
114 add_custom_command(
115 OUTPUT ${lintdep_witness}
116 COMMAND true
117 DEPENDS lint-${slug}-deps
118 COMMENT "Makefile stub for lint-${slug} dependency fence")
119 endif()
120
121 set(bzl_lintdeps)
122 set(bzl_fmtdeps)
123 set(bzl_chkfmtdeps)
124 foreach(filename ${_args_BZL})
125 get_filename_component(_dirpath ${CMAKE_CURRENT_BINARY_DIR}/${filename}
126 DIRECTORY)
127
128 add_custom_command(
129 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
130 COMMAND buildifier -indent 2 -mode check
131 ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
132 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
133 COMMAND ${CMAKE_COMMAND} -E touch
134 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
135 DEPENDS ${filename} ${lintdep_witness}
136 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
137 list(APPEND bzl_lintdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp)
138
139 add_custom_command(
140 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
141 COMMAND buildifier -indent 2 -mode fix
142 ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
143 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
144 COMMAND ${CMAKE_COMMAND} -E touch
145 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
146 DEPENDS ${filename}
147 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
148 list(APPEND bzl_fmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp)
149
150 add_custom_command(
151 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
152 COMMAND buildifier -indent 2 -mode check
153 ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
154 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
155 COMMAND ${CMAKE_COMMAND} -E touch
156 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
157 DEPENDS ${filename}
158 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
159 list(APPEND bzl_chkfmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt)
160 endforeach()
161
162 set(cmake_lintdeps)
163 set(cmake_fmtdeps)
164 set(cmake_chkfmtdeps)
165 foreach(filename ${_args_CMAKE})
166 get_filename_component(_dirpath ${CMAKE_CURRENT_BINARY_DIR}/${filename}
167 DIRECTORY)
168
169 add_custom_command(
170 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
171 COMMAND ${CMAKE_LINT_CMD} --suppress-decorations ${filename}
172 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
173 COMMAND ${CMAKE_COMMAND} -E touch
174 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
175 DEPENDS ${filename} ${lintdep_witness}
176 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
177 list(APPEND cmake_lintdeps
178 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp)
179
180 add_custom_command(
181 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
182 COMMAND ${CMAKE_FORMAT_CMD} -i ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
183 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
184 COMMAND ${CMAKE_COMMAND} -E touch
185 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
186 DEPENDS ${filename}
187 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
188 list(APPEND cmake_fmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp)
189
190 add_custom_command(
191 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
192 COMMAND ${CMAKE_FORMAT_CMD} --check
193 ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
194 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
195 COMMAND ${CMAKE_COMMAND} -E touch
196 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
197 DEPENDS ${filename}
198 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
199 list(APPEND cmake_chkfmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt)
200 endforeach()
201
202 set(cc_lintdeps)
203 set(cc_fmtdeps)
204 set(cc_chkfmtdeps)
205 foreach(filename ${_args_CC})
206 get_filename_component(_dirpath ${CMAKE_CURRENT_BINARY_DIR}/${filename}
207 DIRECTORY)
208
209 if("${filename}" MATCHES ".*\\.(c|(cc)|(cpp))$")
210 # NOTE(josh): clang-tidy doesn't work on header files. It will check
211 # headers that it finds in the inclusion of translation units it
212 # understands
213 add_custom_command(
214 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.tidy
215 COMMAND
216 clang-tidy-8 -p ${CMAKE_BINARY_DIR} -header-filter=${CMAKE_SOURCE_DIR}
217 ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
218 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
219 COMMAND ${CMAKE_COMMAND} -E touch
220 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.tidy
221 DEPENDS ${filename} ${_args_CCDEPENDS} ${lintdep_witness}
222 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
223 list(APPEND cc_lintdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.tidy)
224 endif()
225
226 add_custom_command(
227 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.cpplint
228 COMMAND cpplint ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
229 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
230 COMMAND ${CMAKE_COMMAND} -E touch
231 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.cpplint
232 DEPENDS ${filename} ${_args_CCDEPENDS} ${lintdep_witness}
233 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
234 list(APPEND cc_lintdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.cpplint)
235
236 add_custom_command(
237 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
238 COMMAND clang-format-8 -style file -i ${filename}
239 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
240 COMMAND ${CMAKE_COMMAND} -E touch
241 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
242 DEPENDS ${filename} ${_args_CCDEPENDS}
243 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
244 list(APPEND cc_fmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp)
245
246 add_custom_command(
247 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
248 COMMAND
249 COMMAND clang-format-8 -style file ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
250 "|" diff -u ${CMAKE_CURRENT_SOURCE_DIR}/${filename} -
251 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
252 COMMAND ${CMAKE_COMMAND} -E touch
253 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
254 DEPENDS ${filename} ${_args_CCDEPENDS}
255 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
256 list(APPEND cc_chkfmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt)
257 endforeach()
258
259 set(js_lintdeps)
260 set(js_fmtdeps)
261 set(js_chkfmtdeps)
262 foreach(filename ${_args_JS})
263 get_filename_component(_dirpath ${CMAKE_CURRENT_BINARY_DIR}/${filename}
264 DIRECTORY)
265
266 add_custom_command(
267 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
268 COMMAND eslint ${filename}
269 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
270 COMMAND ${CMAKE_COMMAND} -E touch
271 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
272 DEPENDS ${filename} ${lintdep_witness}
273 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
274 list(APPEND js_lintdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp)
275
276 add_custom_command(
277 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
278 COMMAND js-beautify -r ${filename}
279 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
280 COMMAND ${CMAKE_COMMAND} -E touch
281 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
282 DEPENDS ${filename}
283 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
284 list(APPEND js_fmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp)
285
286 add_custom_command(
287 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
288 COMMAND js-beautify ${CMAKE_CURRENT_SOURCE_DIR}/${filename} "|" diff -u
289 ${CMAKE_CURRENT_SOURCE_DIR}/${filename} -
290 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
291 COMMAND ${CMAKE_COMMAND} -E touch
292 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
293 DEPENDS ${filename}
294 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
295 list(APPEND js_chkfmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt)
296 endforeach()
297
298 set(py_lintdeps)
299 set(py_fmtdeps)
300 set(py_chkfmtdeps)
301 foreach(filename ${_args_PY})
302 get_filename_component(_dirpath ${CMAKE_CURRENT_BINARY_DIR}/${filename}
303 DIRECTORY)
304
305 add_custom_command(
306 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
307 # NOTE(josh): --rcfile= is required because some of our python
308 # files are note entirely within the package tree from the root of
309 # the repository. As such pylint will not match the rcfile in the
310 # root of the repository.
311 COMMAND
312 env PYTHONPATH=${_pythonpath} pylint
313 --rcfile=${CMAKE_SOURCE_DIR}/pylintrc -sn -rn
314 ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
315 # NOTE(josh): flake8 tries to use semaphores which fail in our
316 # containers https://bugs.python.org/issue3770 (probably due to
317 # /proc/shmem or something not being mounted)
318 COMMAND env PYTHONPATH=${_pythonpath} flake8 --jobs 1
319 ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
320 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
321 COMMAND ${CMAKE_COMMAND} -E touch
322 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
323 DEPENDS ${filename}
324 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
325 list(APPEND py_lintdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp)
326
327 add_custom_command(
328 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
329 COMMAND autopep8 -i ${filename}
330 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
331 COMMAND ${CMAKE_COMMAND} -E touch
332 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
333 DEPENDS ${filename}
334 WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR})
335 list(APPEND py_fmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp)
336
337 add_custom_command(
338 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
339 COMMAND autopep8 ${CMAKE_CURRENT_SOURCE_DIR}/${filename} "|" diff -u
340 ${CMAKE_CURRENT_SOURCE_DIR}/${filename} -
341 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
342 COMMAND ${CMAKE_COMMAND} -E touch
343 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
344 DEPENDS ${filename}
345 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
346 list(APPEND py_chkfmtdeps ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt)
347 endforeach()
348
349 set(shell_lintdeps)
350 set(shell_fmtdeps)
351 set(shell_chkfmtdeps)
352 foreach(filename ${_args_SHELL})
353 get_filename_component(_dirpath ${CMAKE_CURRENT_BINARY_DIR}/${filename}
354 DIRECTORY)
355
356 add_custom_command(
357 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
358 COMMAND shellcheck ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
359 COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
360 COMMAND ${CMAKE_COMMAND} -E touch
361 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp
362 DEPENDS ${filename} ${lintdep_witness}
363 WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
364 list(APPEND shell_lintdeps
365 ${CMAKE_CURRENT_BINARY_DIR}/${filename}.lintstamp)
366
367 # NOTE(josh): beautysh is broken. It destroys shell scripts
368 # ~~~
369 # add_custom_command(
370 # OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
371 # COMMAND beautysh --indent-size=2 ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
372 # COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
373 # COMMAND ${CMAKE_COMMAND} -E touch
374 # ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp
375 # DEPENDS ${filename}
376 # WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
377 # list(APPEND shell_fmtdeps
378 # ${CMAKE_CURRENT_BINARY_DIR}/${filename}.fmtstamp)
379 #
380 # add_custom_command(
381 # OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
382 # COMMAND beautysh --indent-size=2 --check
383 # ${CMAKE_CURRENT_SOURCE_DIR}/${filename}
384 # COMMAND ${CMAKE_COMMAND} -E make_directory ${_dirpath}
385 # COMMAND ${CMAKE_COMMAND} -E touch
386 # ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt
387 # DEPENDS ${filename}
388 # WORKING_DIRECTORY ${CMAKE_SOURCE_DIR})
389 # list(APPEND shell_chkfmtdeps
390 # ${CMAKE_CURRENT_BINARY_DIR}/${filename}.chkfmt)
391 # ~~~
392 endforeach()
393
394 if(unknown_files)
395 string(REPLACE ";" "\n " filelist "${unknown_files}")
396 message(
397 WARNING "The following files will not be linted/formatted because their"
398 " extension is not recognized: \n ${filelist}")
399 endif()
400
401 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${slug}.lint-manifest "")
402 foreach(listname _args_CC _args_CMAKE _args_JS _args_PY _args_SHELL)
403 if(${listname})
404 string(REPLACE ";" "\n" filenames "${${listname}}")
405 file(APPEND ${CMAKE_CURRENT_BINARY_DIR}/${slug}.lint-manifest
406 "${filenames}\n")
407 endif()
408 endforeach()
409
410 set(langslugs bzl cc cmake js py shell)
411 add_custom_target(lint-${slug})
412 add_dependencies(lint lint-${slug})
413 foreach(langslug ${langslugs})
414 if(${langslug}_lintdeps)
415 add_custom_target(lint-${langslug}-${slug}
416 DEPENDS ${${langslug}_lintdeps})
417 add_dependencies(lint-${slug} lint-${langslug}-${slug})
418 endif()
419 endforeach()
420
421 add_custom_target(format-${slug})
422 add_dependencies(format format-${slug})
423 foreach(langslug ${langslugs})
424 if(${langslug}_fmtdeps)
425 add_custom_target(format-${langslug}-${slug}
426 DEPENDS ${${langslug}_fmtdeps})
427 add_dependencies(format-${slug} format-${langslug}-${slug})
428 endif()
429 endforeach()
430
431 add_custom_target(chkfmt-${slug})
432 add_dependencies(chkfmt chkfmt-${slug})
433 foreach(langslug ${langslugs})
434 if(${langslug}_chkfmtdeps)
435 add_custom_target(chkfmt-${langslug}-${slug}
436 DEPENDS ${${langslug}_chkfmtdeps})
437 add_dependencies(chkfmt-${slug} chkfmt-${langslug}-${slug})
438 endif()
439 endforeach()
440 endfunction()