Debian Codegraph @

src/camel_snake_kebab/internals/macros.cljc

raw
1 (ns ^:no-doc camel-snake-kebab.internals.macros
2 #?(:cljs (:refer-clojure :exclude [resolve]))
3 (:require [camel-snake-kebab.internals.alter-name :refer [alter-name]]
4 [camel-snake-kebab.internals.misc :refer [convert-case]]))
5
6 #?(:cljs
7 (defn resolve [sym]
8 ;; On self-hosted ClojureScript, macros are evaluated under the `:cljs` conditional branch
9 ;; In that case, we need to use `eval` in order to resolve variables instead of `resolve`
10 (eval `(~'var ~sym))))
11
12 (defn type-preserving-function [case-label first-fn rest-fn sep]
13 `(defn ~(symbol (str "->" case-label)) [s# & rest#]
14 (let [convert-case# #(apply convert-case ~first-fn ~rest-fn ~sep % rest#)]
15 (alter-name s# convert-case#))))
16
17 (defn type-converting-functions [case-label first-fn rest-fn sep]
18 (letfn [(make-name [type-label]
19 (->> (str case-label " " type-label)
20 (convert-case (resolve first-fn) (resolve rest-fn) sep)
21 (str "->")
22 (symbol)))]
23 (for [[type-label type-converter] {"string" `identity "symbol" `symbol "keyword" `keyword}]
24 `(defn ~(make-name type-label) [s# & rest#]
25 (~type-converter (apply convert-case ~first-fn ~rest-fn ~sep (name s#) rest#))))))
26
27 (defmacro defconversion [case-label first-fn rest-fn sep]
28 `(do ~(type-preserving-function case-label first-fn rest-fn sep)
29 ~@(type-converting-functions case-label first-fn rest-fn sep)))