Debian Codegraph @

podofo/playground/CMakeLists.txt

raw
1 cmake_minimum_required(VERSION 3.23)
2
3 if ("${CMAKE_BUILD_TYPE}" STREQUAL "")
4 set(CMAKE_BUILD_TYPE "Release")
5 endif()
6
7 # Clean CMAKE_CONFIGURATION_TYPES. Only one configuration will be used
8 unset(CMAKE_CONFIGURATION_TYPES CACHE) # It will also remove it from GUI
9 set(CMAKE_CONFIGURATION_TYPES "${CMAKE_BUILD_TYPE}")
10
11 project(podofo)
12 enable_testing() # Needed to enable "make test" from binary dir
13
14 # An useful variable to check if we are running from playground
15 set(PODOFO_PLAYGROUND TRUE)
16
17 # Always build unsupported tools in the playground
18 option(PODOFO_BUILD_UNSUPPORTED_TOOLS "Build unsupported tools" TRUE)
19
20 # Enable Win32 GDI font search on Windows
21 if(WIN32)
22 option(PODOFO_WITH_WIN32GDI_FONT_SEARCH "Use Win32 GDI for font search" ON)
23 endif()
24
25 if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
26 set(ARCH "Win64")
27 elseif(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
28 execute_process(COMMAND uname -m OUTPUT_VARIABLE UNAME_M OUTPUT_STRIP_TRAILING_WHITESPACE)
29 set(ARCH "macos-${UNAME_M}")
30 elseif(CMAKE_SYSTEM_NAME STREQUAL "Linux")
31 set(ARCH "linux-x86_64")
32 else()
33 message(FATAL_ERROR "Unsupported operating system ${CMAKE_SYSTEM_NAME}")
34 endif()
35 set(ARCH "${ARCH}" CACHE STRING "" FORCE)
36
37 if ("${PODOFO_DIR}" STREQUAL "")
38 get_filename_component(PODOFO_DIR ${CMAKE_CURRENT_SOURCE_DIR} DIRECTORY)
39 endif()
40
41 set(DEPS_PATH "$ENV{PODOFO_DEPS_PATH}")
42 if ("${DEPS_PATH}" STREQUAL "")
43 set(DEPS_PATH "${PODOFO_DIR}/extern/deps/3rdparty")
44 endif()
45
46 if(NOT EXISTS "${DEPS_PATH}")
47 message(FATAL_ERROR "Deps path doesn't exists: try fetch git submodules with:\n git submodule update --init")
48 endif()
49
50 cmake_host_system_information(RESULT CORE_COUNT QUERY NUMBER_OF_PHYSICAL_CORES)
51
52 if (MSVC)
53 # Set parallel compilation by default in Visual Studio
54 add_compile_options("/MP${CORE_COUNT}")
55
56 # Ignore warnings about missing pdbs
57 set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} /ignore:4099")
58 set(CMAKE_SHARED_LINKER_FLAGS "${CMAKE_SHARED_LINKER_FLAGS} /ignore:4099")
59 set(CMAKE_STATIC_LINKER_FLAGS "${CMAKE_STATIC_LINKER_FLAGS} /ignore:4099")
60 endif()
61
62 message("ARCHITECTURE: ${ARCH}")
63 message("PODOFO_DIR: ${PODOFO_DIR}")
64 message("DEPS_PATH: ${DEPS_PATH}")
65
66 # Set include folders for find_package()
67 list(APPEND CMAKE_INCLUDE_PATH
68 "${DEPS_PATH}/zlib/include"
69 "${DEPS_PATH}/libxml2/include"
70 "${DEPS_PATH}/fontconfig/include"
71 "${DEPS_PATH}/freetype/include"
72 "${DEPS_PATH}/libpng/include"
73 "${DEPS_PATH}/libjpeg/include"
74 "${DEPS_PATH}/libtiff/include"
75 "${DEPS_PATH}/openssl/include"
76 "${DEPS_PATH}/lcms2/include"
77 )
78
79 # Set library folders for find_package()
80 list(APPEND CMAKE_LIBRARY_PATH
81 "${DEPS_PATH}/zlib/lib/${ARCH}"
82 "${DEPS_PATH}/libxml2/lib/${ARCH}"
83 "${DEPS_PATH}/freetype/lib/${ARCH}"
84 "${DEPS_PATH}/fontconfig/lib/${ARCH}"
85 "${DEPS_PATH}/libpng/lib/${ARCH}"
86 "${DEPS_PATH}/libjpeg/lib/${ARCH}"
87 "${DEPS_PATH}/libtiff/lib/${ARCH}"
88 "${DEPS_PATH}/openssl/lib/${ARCH}"
89 "${DEPS_PATH}/lcms2/lib/${ARCH}"
90 )
91
92 # Set use libxml2 static for fontconfig
93 add_compile_definitions(LIBXML_STATIC)
94
95 # Enable GPL2 only tests
96 # TODO: Remove me
97 add_compile_definitions(PODOFO_ENABLE_GPL2_TESTS)
98
99 # Don't search dependencies in sysroot. This avoid
100 # potential mismatches
101 set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY NEVER)
102 set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE NEVER)
103 set(CMAKE_FIND_ROOT_PATH_MODE_PACKAGE NEVER)
104
105 if(WIN32)
106 if ("${CMAKE_BUILD_TYPE}" STREQUAL "Debug")
107 set(LIB_SUFFIX "d")
108 endif()
109
110 # Following libraries find-modules have issues in correctly
111 # determining the right optimized/debug library so we do it manually
112
113 # OpenSSL
114 set(OPENSSL_INCLUDE_DIR "${DEPS_PATH}/openssl/include" CACHE PATH "" FORCE)
115 set(LIB_EAY_DEBUG "${DEPS_PATH}/openssl/lib/${ARCH}/cryptod.lib" CACHE FILEPATH "" FORCE)
116 set(LIB_EAY_RELEASE "${DEPS_PATH}/openssl/lib/${ARCH}/crypto.lib" CACHE FILEPATH "" FORCE)
117 set(SSL_EAY_DEBUG "${DEPS_PATH}/openssl/lib/${ARCH}/ssld.lib" CACHE FILEPATH "" FORCE)
118 set(SSL_EAY_RELEASE "${DEPS_PATH}/openssl/lib/${ARCH}/ssl.lib" CACHE FILEPATH "" FORCE)
119 # Libxml2
120 set(LIBXML2_LIBRARY "${DEPS_PATH}/libxml2/lib/${ARCH}/libxml2${LIB_SUFFIX}.lib" CACHE FILEPATH "" FORCE)
121 # Fontconfig
122 set(Fontconfig_LIBRARY "${DEPS_PATH}/fontconfig/lib/${ARCH}/fontconfig${LIB_SUFFIX}.lib" CACHE FILEPATH "" FORCE)
123 else()
124 set(PLATFORM_SYSTEM_LIBRARIES "${DEPS_PATH}/bzip2/lib/${ARCH}/libbz2.a" "${DEPS_PATH}/libuuid/lib/${ARCH}/libuuid.a")
125 endif()
126
127 add_subdirectory("${PODOFO_DIR}" "${CMAKE_BINARY_DIR}/podofo")