Debian Codegraph @

wine/wow64/CMakeLists.txt

raw
1 cmake_minimum_required(VERSION 3.13)
2 project(wowbox64 C ASM)
3
4 if(${CMAKE_VERSION} VERSION_LESS "3.12.2")
5 find_package(PythonInterp 3)
6 if(NOT PYTHONINTERP_FOUND)
7 message( FATAL_ERROR "You need a Python interpreter, CMake will exit." )
8 endif()
9 if(${PYTHON_VERSION_MAJOR} LESS 3)
10 message( FATAL_ERROR "You need a Python 3 interpreter, CMake will exit." )
11 endif()
12 else()
13 find_package(Python3)
14 if(NOT Python3_Interpreter_FOUND)
15 message( FATAL_ERROR "You need a Python interpreter, CMake will exit." )
16 endif()
17 set(PYTHON_EXECUTABLE ${Python3_EXECUTABLE} CACHE INTERNAL "The Python3 executable" FORCE)
18 endif()
19
20 set(BOX64_ROOT "${CMAKE_SOURCE_DIR}/../..")
21
22 string(REPLACE "," ";" DYNAREC_ASM "${DYNAREC_ASM_STR}")
23 string(REPLACE "," ";" DYNAREC_PASS "${DYNAREC_PASS_STR}")
24 string(REPLACE "," ";" INTERPRETER "${INTERPRETER_STR}")
25
26 set(WOW64_MAIN_SRC
27 "${BOX64_ROOT}/wine/common/crt.c"
28 "${BOX64_ROOT}/wine/common/wrt.c"
29 "${BOX64_ROOT}/wine/wow64/wowbox64.c"
30 )
31
32 set(MUSL_SRC
33 "${BOX64_ROOT}/external/musl/__cos.c"
34 "${BOX64_ROOT}/external/musl/__math_divzero.c"
35 "${BOX64_ROOT}/external/musl/__math_invalid.c"
36 "${BOX64_ROOT}/external/musl/__rem_pio2_large.c"
37 "${BOX64_ROOT}/external/musl/__rem_pio2.c"
38 "${BOX64_ROOT}/external/musl/__sin.c"
39 "${BOX64_ROOT}/external/musl/cos.c"
40 "${BOX64_ROOT}/external/musl/exp_data.c"
41 "${BOX64_ROOT}/external/musl/exp2.c"
42 "${BOX64_ROOT}/external/musl/expm1.c"
43 "${BOX64_ROOT}/external/musl/frexp.c"
44 "${BOX64_ROOT}/external/musl/ldexp.c"
45 "${BOX64_ROOT}/external/musl/log1p.c"
46 "${BOX64_ROOT}/external/musl/log2_data.c"
47 "${BOX64_ROOT}/external/musl/log2.c"
48 "${BOX64_ROOT}/external/musl/scalbn.c"
49 "${BOX64_ROOT}/external/musl/sin.c"
50 "${BOX64_ROOT}/external/musl/sincos.c"
51 "${BOX64_ROOT}/external/musl/sqrt_data.c"
52 "${BOX64_ROOT}/external/musl/sqrt.c"
53 "${BOX64_ROOT}/external/musl/sqrtf.c"
54 )
55
56 set_source_files_properties(${DYNAREC_ASM} PROPERTIES COMPILE_OPTIONS "-mcpu=cortex-a76")
57
58 foreach(STEP_VALUE RANGE 3)
59 add_library(wow64_dynarec_pass${STEP_VALUE} OBJECT ${DYNAREC_PASS})
60 target_compile_definitions(wow64_dynarec_pass${STEP_VALUE} PRIVATE STEP=${STEP_VALUE})
61 endforeach()
62
63 add_library(wow64_test_interpreter OBJECT ${INTERPRETER})
64 set_target_properties(wow64_test_interpreter PROPERTIES COMPILE_DEFINITIONS "TEST_INTERPRETER")
65
66 set(WOW64_BOX64CPU_SRC
67 "${BOX64_ROOT}/src/build_info.c"
68 "${BOX64_ROOT}/src/custommem.c"
69 "${BOX64_ROOT}/src/dynarec/arm64/arm64_immenc.c"
70 "${BOX64_ROOT}/src/dynarec/arm64/arm64_printer.c"
71 "${BOX64_ROOT}/src/dynarec/arm64/dynarec_arm64_arch.c"
72 "${BOX64_ROOT}/src/dynarec/arm64/dynarec_arm64_functions.c"
73 "${BOX64_ROOT}/src/dynarec/arm64/dynarec_arm64_jmpnext.c"
74 "${BOX64_ROOT}/src/dynarec/arm64/dynarec_arm64_consts.c"
75 "${BOX64_ROOT}/src/dynarec/arm64/updateflags_arm64.c"
76 "${BOX64_ROOT}/src/dynarec/dynablock.c"
77 "${BOX64_ROOT}/src/dynarec/dynarec_native_functions.c"
78 "${BOX64_ROOT}/src/dynarec/dynarec_native.c"
79 "${BOX64_ROOT}/src/dynarec/dynarec.c"
80 "${BOX64_ROOT}/src/dynarec/dynacache_reloc.c"
81 "${BOX64_ROOT}/src/emu/x64compstrings.c"
82 "${BOX64_ROOT}/src/emu/x64emu.c"
83 "${BOX64_ROOT}/src/emu/x64primop.c"
84 "${BOX64_ROOT}/src/emu/x64shaext.c"
85 "${BOX64_ROOT}/src/emu/x64test.c"
86 "${BOX64_ROOT}/src/emu/x64trace.c"
87 "${BOX64_ROOT}/src/emu/x64run_private.c"
88 "${BOX64_ROOT}/src/emu/x87emu_private.c"
89 "${BOX64_ROOT}/src/os/backtrace.c"
90 "${BOX64_ROOT}/src/os/os_wine.c"
91 "${BOX64_ROOT}/src/os/hostext_common.c"
92 "${BOX64_ROOT}/src/os/hostext_wine.c"
93 "${BOX64_ROOT}/src/os/freq_wine.c"
94 "${BOX64_ROOT}/src/os/symbolfuncs_wine.c"
95 "${BOX64_ROOT}/src/os/emit_signal_wine.c"
96 "${BOX64_ROOT}/src/os/perfmap.c"
97 "${BOX64_ROOT}/src/os/random_wine.c"
98 "${BOX64_ROOT}/src/os/my_cpuid.c"
99 "${BOX64_ROOT}/src/os/sysinfo.c"
100 "${BOX64_ROOT}/src/tools/alternate.c"
101 "${BOX64_ROOT}/src/tools/bitutils.c"
102 "${BOX64_ROOT}/src/tools/env.c"
103 "${BOX64_ROOT}/src/tools/dynacache.c"
104 "${BOX64_ROOT}/src/tools/rbtree.c"
105 )
106
107 add_library(wowbox64 SHARED ${WOW64_MAIN_SRC} ${MUSL_SRC} ${WOW64_BOX64CPU_SRC} ${INTERPRETER} ${DYNAREC_ASM}
108 $<TARGET_OBJECTS:wow64_dynarec_pass0>
109 $<TARGET_OBJECTS:wow64_dynarec_pass1>
110 $<TARGET_OBJECTS:wow64_dynarec_pass2>
111 $<TARGET_OBJECTS:wow64_dynarec_pass3>
112 $<TARGET_OBJECTS:wow64_test_interpreter>
113 "${BOX64_ROOT}/wine/wow64/wowbox64.def")
114
115 include_directories(
116 "${BOX64_ROOT}/src/include"
117 "${BOX64_ROOT}/src"
118 "${BOX64_ROOT}/wine/include"
119 "${BOX64_ROOT}/external/musl"
120 "${BOX64_ROOT}/external/musl/internal"
121 )
122
123 set(DYNACACHE_HASH_HEADER "${BOX64_ROOT}/src/dynacache_hashes.h")
124 add_custom_target(generate_dynacache_hashes
125 COMMAND "${PYTHON_EXECUTABLE}" "${BOX64_ROOT}/tools/gen_dynacache_hashes.py"
126 --root "${BOX64_ROOT}"
127 --output "${DYNACACHE_HASH_HEADER}"
128 BYPRODUCTS "${DYNACACHE_HASH_HEADER}"
129 VERBATIM
130 )
131 add_dependencies(wowbox64 generate_dynacache_hashes)
132
133 set(DLLTOOL aarch64-w64-mingw32-dlltool)
134
135 function(import_dll name)
136 add_custom_command(
137 OUTPUT ${CMAKE_CURRENT_BINARY_DIR}/${name}.a
138 COMMAND ${DLLTOOL}
139 -D ${name}.dll
140 -d ${BOX64_ROOT}/wine/${name}.def
141 -l ${CMAKE_CURRENT_BINARY_DIR}/${name}.a
142 -k
143 DEPENDS ${BOX64_ROOT}/wine/${name}.def
144 COMMENT "Generating import library ${name}.a from ${name}.def"
145 )
146 add_custom_target(generate_${name}_import_lib DEPENDS ${CMAKE_CURRENT_BINARY_DIR}/${name}.a)
147 add_dependencies(wowbox64 generate_${name}_import_lib)
148 target_link_libraries(wowbox64 PRIVATE ${CMAKE_CURRENT_BINARY_DIR}/${name}.a)
149 endfunction()
150
151
152 import_dll(ntdll)
153 import_dll(wow64)
154
155 # always enable DynaRec, only supports ARM64 for now.
156 add_compile_definitions(DYNAREC ARM64)
157
158 target_compile_options(wowbox64 PRIVATE -Wno-inconsistent-dllimport)
159 target_link_options(wowbox64 PRIVATE -nostdlib -nodefaultlibs
160 -lclang_rt.builtins-aarch64
161 -Wl,--image-base,0x004c0000
162 -Wl,/ignore:4217 # LNK4217: locally defined symbol imported
163 )
164 set_target_properties(wowbox64 PROPERTIES
165 PREFIX ""
166 SUFFIX ".dll"
167 OUTPUT_NAME "wowbox64"
168 )
169
170 add_custom_command(
171 TARGET wowbox64 POST_BUILD
172 COMMAND "${PYTHON_EXECUTABLE}" ${CMAKE_SOURCE_DIR}/../override_wine_builtin.py $<TARGET_FILE:wowbox64>
173 )
174
175 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_BINARY_DIR}/bin)