Debian Codegraph @

src/vendor/azure-uamqp-c/deps/azure-c-shared-utility/configs/azure_iot_build_rules.cmake

raw
1 #Copyright (c) Microsoft. All rights reserved.
2 #Licensed under the MIT license. See LICENSE file in the project root for full license information.
3
4 # Silences a CMake warning, no apparent effect on the Azure IoT SDK
5 if(POLICY CMP0042)
6 cmake_policy(SET CMP0042 NEW)
7 endif()
8
9 #Use solution folders.
10 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
11
12 # Build with -fPIC always
13 set(CMAKE_POSITION_INDEPENDENT_CODE TRUE)
14
15 option(run_valgrind "set run_valgrind to ON if tests are to be run under valgrind/helgrind/drd. Default is OFF" OFF)
16 set(compileOption_C "" CACHE STRING "passes a string to the command line of the C compiler")
17 set(compileOption_CXX "" CACHE STRING "passes a string to the command line of the C++ compiler")
18
19 # These are the include folders. (assumes that this file is in a subdirectory of c-utility)
20 get_filename_component(SHARED_UTIL_FOLDER ${CMAKE_CURRENT_LIST_DIR} DIRECTORY)
21 set(SHARED_UTIL_FOLDER "${SHARED_UTIL_FOLDER}" CACHE INTERNAL "this is the sharedLib directory" FORCE)
22 set(SHARED_UTIL_INC_FOLDER ${SHARED_UTIL_FOLDER}/inc CACHE INTERNAL "this is what needs to be included if using sharedLib lib" FORCE)
23 set(SHARED_UTIL_SRC_FOLDER ${SHARED_UTIL_FOLDER}/src CACHE INTERNAL "this is what needs to be included when doing include sources" FORCE)
24 set(SHARED_UTIL_ADAPTER_FOLDER "${SHARED_UTIL_FOLDER}/adapters" CACHE INTERNAL "this is where the adapters live" FORCE)
25 # PAL will eventually absorb the contents of SHARED_UTIL_ADAPTER_FOLDER
26 set(SHARED_UTIL_PAL_FOLDER "${SHARED_UTIL_FOLDER}/pal" CACHE INTERNAL "this is the PAL common sources directory" FORCE)
27 set(SHARED_UTIL_PAL_INC_FOLDER "${SHARED_UTIL_FOLDER}/pal/inc" CACHE INTERNAL "this is the PAL include directory" FORCE)
28
29
30 #making a global variable to know if we are on linux, windows, or macosx.
31 if(CMAKE_SYSTEM_NAME STREQUAL "Windows")
32 set(WINDOWS TRUE)
33 elseif(CMAKE_SYSTEM_NAME STREQUAL "Linux")
34 set(LINUX TRUE)
35 #on Linux, enable valgrind
36 #these commands (MEMORYCHECK...) need to apear BEFORE include(CTest) or they will not have any effect
37 find_program(MEMORYCHECK_COMMAND valgrind)
38 set(MEMORYCHECK_COMMAND_OPTIONS "--leak-check=full --error-exitcode=1")
39 elseif(CMAKE_SYSTEM_NAME STREQUAL "Darwin")
40 set(MACOSX TRUE)
41 endif()
42
43 include(CTest)
44
45 include_directories(${SHARED_UTIL_INC_FOLDER})
46
47 # OS-specific header files for ref counting
48 if(MSVC)
49 include_directories(${SHARED_UTIL_PAL_FOLDER}/windows)
50 else()
51 include_directories(${SHARED_UTIL_PAL_FOLDER}/linux)
52 endif()
53
54 # if the compiler check fails (such as for iOS) header search will also fail - this allows it to be suppressed
55 if(NOT suppress_header_searches)
56 include(CheckIncludeFiles)
57 CHECK_INCLUDE_FILES(stdint.h HAVE_STDINT_H)
58 CHECK_INCLUDE_FILES(stdbool.h HAVE_STDBOOL_H)
59 else()
60 message(STATUS "Bypassing header search")
61 set(HAVE_STDINT_H TRUE)
62 set(HAVE_STDBOOL_H TRUE)
63 endif()
64
65 if ((NOT HAVE_STDINT_H) OR (NOT HAVE_STDBOOL_H))
66 include_directories(${SHARED_UTIL_INC_FOLDER}/azure_c_shared_utility/windowsce)
67 endif()
68
69 # System-specific compiler flags
70 if(MSVC)
71 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W3")
72 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} /W3")
73 elseif(UNIX) #LINUX OR APPLE
74 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Werror")
75 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror")
76 if(NOT (IN_OPENWRT OR APPLE))
77 # _XOPEN_SOURCE=500 is required for glibc to expose random and srandom.
78 set (CMAKE_C_FLAGS "-D_POSIX_C_SOURCE=200112L -D_XOPEN_SOURCE=500 ${CMAKE_C_FLAGS}")
79 endif()
80 endif()
81
82 enable_testing()
83
84 include(CheckSymbolExists)
85 function(detect_architecture symbol arch)
86 if (NOT DEFINED ARCHITECTURE OR ARCHITECTURE STREQUAL "")
87 set(CMAKE_REQUIRED_QUIET 1)
88 check_symbol_exists("${symbol}" "" ARCHITECTURE_${arch})
89 unset(CMAKE_REQUIRED_QUIET)
90
91 # The output variable needs to be unique across invocations otherwise
92 # CMake's crazy scope rules will keep it defined
93 if (ARCHITECTURE_${arch})
94 set(ARCHITECTURE "${arch}" PARENT_SCOPE)
95 set(ARCHITECTURE_${arch} 1 PARENT_SCOPE)
96 add_definitions(-DARCHITECTURE_${arch}=1)
97 endif()
98 endif()
99 endfunction()
100 if (MSVC)
101 detect_architecture("_M_AMD64" x86_64)
102 detect_architecture("_M_IX86" x86)
103 detect_architecture("_M_ARM" ARM)
104 else()
105 detect_architecture("__x86_64__" x86_64)
106 detect_architecture("__i386__" x86)
107 detect_architecture("__arm__" ARM)
108 endif()
109 if (NOT DEFINED ARCHITECTURE OR ARCHITECTURE STREQUAL "")
110 set(ARCHITECTURE "GENERIC")
111 endif()
112 message(STATUS "target architecture: ${ARCHITECTURE}")
113
114 # if any compiler has a command line switch called "OFF" then it will need special care
115 if (NOT "${compileOption_C}" STREQUAL "")
116 set(CMAKE_C_FLAGS "${compileOption_C} ${CMAKE_C_FLAGS}")
117 endif()
118
119 if (NOT "${compileOption_CXX}" STREQUAL "")
120 set(CMAKE_CXX_FLAGS "${compileOption_CXX} ${CMAKE_CXX_FLAGS}")
121 endif()
122
123 include(CheckCXXCompilerFlag)
124 CHECK_CXX_COMPILER_FLAG("-std=c++11" CXX_FLAG_CXX11)
125
126 macro(compileAsC99)
127 if (CMAKE_VERSION VERSION_LESS "3.1")
128 if (CMAKE_C_COMPILER_ID STREQUAL "GNU")
129 set (CMAKE_C_FLAGS "--std=c99 ${CMAKE_C_FLAGS}")
130 if (CXX_FLAG_CXX11)
131 set (CMAKE_CXX_FLAGS "--std=c++11 ${CMAKE_CXX_FLAGS}")
132 else()
133 set (CMAKE_CXX_FLAGS "--std=c++0x ${CMAKE_CXX_FLAGS}")
134 endif()
135 endif()
136 else()
137 set (CMAKE_C_STANDARD 99)
138 set (CMAKE_CXX_STANDARD 11)
139 endif()
140 endmacro(compileAsC99)
141
142 macro(compileAsC11)
143 if (CXX_FLAG_CXX11)
144 if (CMAKE_VERSION VERSION_LESS "3.1")
145 if (CMAKE_C_COMPILER_ID STREQUAL "GNU")
146 set (CMAKE_C_FLAGS "--std=c11 ${CMAKE_C_FLAGS}")
147 set (CMAKE_C_FLAGS "-D_POSIX_C_SOURCE=200112L ${CMAKE_C_FLAGS}")
148 set (CMAKE_CXX_FLAGS "--std=c++11 ${CMAKE_CXX_FLAGS}")
149 endif()
150 else()
151 set (CMAKE_C_STANDARD 11)
152 set (CMAKE_CXX_STANDARD 11)
153 endif()
154 else()
155 if (CMAKE_C_COMPILER_ID STREQUAL "GNU")
156 set (CMAKE_C_FLAGS "--std=c99 ${CMAKE_C_FLAGS}")
157 set (CMAKE_CXX_FLAGS "--std=c++0x ${CMAKE_CXX_FLAGS}")
158 else()
159 set (CMAKE_C_STANDARD 11)
160 set (CMAKE_CXX_STANDARD 11)
161 endif()
162 endif()
163 endmacro(compileAsC11)
164
165 function(compileTargetAsC99 theTarget)
166 if (CMAKE_VERSION VERSION_LESS "3.1")
167 if (CMAKE_C_COMPILER_ID STREQUAL "GNU")
168 set_target_properties(${theTarget} PROPERTIES COMPILE_FLAGS "--std=c99")
169 endif()
170 else()
171 set_target_properties(${theTarget} PROPERTIES C_STANDARD 99)
172 set_target_properties(${theTarget} PROPERTIES CXX_STANDARD 11)
173 endif()
174 endfunction()
175
176 function(compileTargetAsC11 theTarget)
177 if (CMAKE_VERSION VERSION_LESS "3.1")
178 if (CMAKE_C_COMPILER_ID STREQUAL "GNU")
179 if (CXX_FLAG_CXX11)
180 set_target_properties(${theTarget} PROPERTIES COMPILE_FLAGS "--std=c11 -D_POSIX_C_SOURCE=200112L")
181 else()
182 set_target_properties(${theTarget} PROPERTIES COMPILE_FLAGS "--std=c99 -D_POSIX_C_SOURCE=200112L")
183 endif()
184 endif()
185 else()
186 set_target_properties(${theTarget} PROPERTIES C_STANDARD 11)
187 set_target_properties(${theTarget} PROPERTIES CXX_STANDARD 11)
188 endif()
189 endfunction()
190
191 macro(generate_cpp_wrapper setVar whatIsBuilding)
192 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${whatIsBuilding}.cxx "#include \"${CMAKE_CURRENT_SOURCE_DIR}/${whatIsBuilding}.c\"")
193 set(${setVar} ${CMAKE_CURRENT_BINARY_DIR}/${whatIsBuilding}.cxx)
194 endmacro(generate_cpp_wrapper)
195
196 macro(generate_cppunittest_wrapper whatIsBuilding)
197 if (${use_cppunittest} AND WIN32)
198 file(WRITE ${CMAKE_CURRENT_BINARY_DIR}/${whatIsBuilding}.cxx "#include \"${CMAKE_CURRENT_SOURCE_DIR}/${whatIsBuilding}.c\"")
199 set(${whatIsBuilding}_test_files ${CMAKE_CURRENT_BINARY_DIR}/${whatIsBuilding}.cxx)
200 #CPP compiler on windows likes to complain about unused local function removed (C4505)
201 #C compiler doesn't like to complain about the same thing
202 set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /wd4505")
203 else()
204 set(${whatIsBuilding}_test_files ${whatIsBuilding}.c)
205 endif()
206 endmacro(generate_cppunittest_wrapper)
207
208 IF((WIN32) AND (NOT(MINGW)))
209 #windows needs this define
210 add_definitions(-D_CRT_SECURE_NO_WARNINGS)
211 # Make warning as error
212 add_definitions(/WX)
213 ELSE()
214 # Make warning as error
215 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Werror")
216 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Werror")
217 ENDIF()
218
219
220 function(add_files_to_install filesToBeInstalled)
221 set(INSTALL_H_FILES ${INSTALL_H_FILES} ${filesToBeInstalled} CACHE INTERNAL "Files that will be installed on the system")
222 endfunction()
223
224 # XCode and stricter warning levels such as -Wall and -Wextra warn about unused
225 # variables and unused static functions, both of which are produced by serializer
226 function(usePermissiveRulesForSamplesAndTests)
227 if (NOT MSVC)
228 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-unused-variable -Wno-unused-function -Wno-missing-braces -Wno-strict-aliasing")
229 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-unused-variable -Wno-unused-function -Wno-missing-braces -Wno-strict-aliasing")
230 if(NOT APPLE AND NOT "${CMAKE_CXX_COMPILER_ID}" STREQUAL "Clang")
231 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-unused-but-set-variable -Wno-clobbered")
232 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -Wno-unused-but-set-variable -Wno-clobbered")
233 endif()
234 set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}" PARENT_SCOPE)
235 set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS}" PARENT_SCOPE)
236 endif()
237 endfunction()
238
239 # For targets which set warning switches as project properties (e.g. XCode)
240 function(setTargetBuildProperties stbp_target)
241 if(XCODE)
242 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_BLOCK_CAPTURE_AUTORELEASING "YES")
243 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_BOOL_CONVERSION "YES")
244 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_COMMA "YES")
245 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_CONSTANT_CONVERSION "YES")
246 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_DEPRECATED_OBJC_IMPLEMENTATIONS "YES")
247 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_EMPTY_BODY "YES")
248 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_ENUM_CONVERSION "YES")
249 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_INFINITE_RECURSION "YES")
250 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_INT_CONVERSION "YES")
251 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_NON_LITERAL_NULL_CONVERSION "YES")
252 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_OBJC_IMPLICIT_RETAIN_SELF "YES")
253 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_OBJC_LITERAL_CONVERSION "YES")
254 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_OBJC_ROOT_CLASS "YES_ERROR")
255 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_RANGE_LOOP_ANALYSIS "YES")
256 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_STRICT_PROTOTYPES "YES")
257 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_SUSPICIOUS_MOVE "YES")
258 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN_UNREACHABLE_CODE "YES")
259 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_CLANG_WARN__DUPLICATE_METHOD_MATCH "YES")
260 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_GCC_WARN_64_TO_32_BIT_CONVERSION "YES")
261 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_GCC_WARN_ABOUT_RETURN_TYPE "YES")
262 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_GCC_WARN_UNDECLARED_SELECTOR "YES")
263 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_GCC_WARN_UNINITIALIZED_AUTOS "YES_AGGRESSIVE")
264 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_GCC_WARN_UNUSED_FUNCTION "YES")
265 set_target_properties(${stbp_target} PROPERTIES XCODE_ATTRIBUTE_GCC_WARN_UNUSED_VARIABLE "YES")
266 endif()
267 endfunction()
268