Debian Codegraph @

LspCpp/third_party/utfcpp/CMakeLists.txt

raw
1 cmake_minimum_required (VERSION 3.0.2)
2 project (utf8cpp VERSION 3.2.2 LANGUAGES CXX)
3
4 if(CMAKE_SOURCE_DIR STREQUAL CMAKE_CURRENT_SOURCE_DIR)
5 set(IS_ROOT_PROJECT ON)
6 else()
7 set(IS_ROOT_PROJECT OFF)
8 endif()
9
10 option(UTF8_TESTS "Enable tests for UTF8-CPP" ${IS_ROOT_PROJECT})
11 option(UTF8_INSTALL "Enable installation for UTF8-CPP" ${IS_ROOT_PROJECT})
12 option(UTF8_SAMPLES "Enable building samples for UTF8-CPP" ${IS_ROOT_PROJECT})
13
14 add_library(utf8cpp INTERFACE)
15 target_include_directories(utf8cpp INTERFACE
16 "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/source>"
17 $<INSTALL_INTERFACE:include/utf8cpp>
18 )
19 add_library(utf8::cpp ALIAS utf8cpp)
20
21 if(UTF8_INSTALL)
22 include(CMakePackageConfigHelpers)
23 if(MSVC)
24 set(DEF_INSTALL_CMAKE_DIR CMake)
25 else()
26 include(GNUInstallDirs) # define CMAKE_INSTALL_*
27 set(DEF_INSTALL_CMAKE_DIR ${CMAKE_INSTALL_LIBDIR}/cmake/utf8cpp)
28 endif()
29
30 write_basic_package_version_file(
31 ${CMAKE_CURRENT_BINARY_DIR}/utf8cppConfigVersion.cmake
32 VERSION ${PROJECT_VERSION}
33 COMPATIBILITY SameMajorVersion
34 )
35
36 configure_package_config_file(
37 ${PROJECT_SOURCE_DIR}/utf8cppConfig.cmake.in
38 ${CMAKE_CURRENT_BINARY_DIR}/utf8cppConfig.cmake
39 INSTALL_DESTINATION ${DEF_INSTALL_CMAKE_DIR}
40 )
41
42 install(DIRECTORY source/ DESTINATION include/utf8cpp)
43 install(TARGETS utf8cpp EXPORT utf8cppTargets)
44 install(EXPORT utf8cppTargets DESTINATION ${DEF_INSTALL_CMAKE_DIR})
45 install(
46 FILES
47 ${CMAKE_CURRENT_BINARY_DIR}/utf8cppConfig.cmake
48 ${CMAKE_CURRENT_BINARY_DIR}/utf8cppConfigVersion.cmake
49 DESTINATION
50 ${DEF_INSTALL_CMAKE_DIR}
51 )
52 endif()
53
54 if(UTF8_SAMPLES)
55 add_executable(docsample ${PROJECT_SOURCE_DIR}/samples/docsample.cpp)
56 target_link_libraries(docsample PRIVATE utf8::cpp)
57 endif()
58
59 if(UTF8_TESTS)
60 enable_testing()
61 add_subdirectory(tests)
62 endif()