| 1 |
######################################################################## |
| 2 |
# Note: CMake support is community-based. The maintainers do not use CMake |
| 3 |
# internally. |
| 4 |
# |
| 5 |
# CMake build script for Google Mock. |
| 6 |
# |
| 7 |
# To run the tests for Google Mock itself on Linux, use 'make test' or |
| 8 |
# ctest. You can select which tests to run using 'ctest -R regex'. |
| 9 |
# For more options, run 'ctest --help'. |
| 10 |
|
| 11 |
option(gmock_build_tests "Build all of Google Mock's own tests." OFF) |
| 12 |
|
| 13 |
# A directory to find Google Test sources. |
| 14 |
if (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/gtest/CMakeLists.txt") |
| 15 |
set(gtest_dir gtest) |
| 16 |
else() |
| 17 |
set(gtest_dir ../googletest) |
| 18 |
endif() |
| 19 |
|
| 20 |
# Defines pre_project_set_up_hermetic_build() and set_up_hermetic_build(). |
| 21 |
include("${gtest_dir}/cmake/hermetic_build.cmake" OPTIONAL) |
| 22 |
|
| 23 |
if (COMMAND pre_project_set_up_hermetic_build) |
| 24 |
# Google Test also calls hermetic setup functions from add_subdirectory, |
| 25 |
# although its changes will not affect things at the current scope. |
| 26 |
pre_project_set_up_hermetic_build() |
| 27 |
endif() |
| 28 |
|
| 29 |
######################################################################## |
| 30 |
# |
| 31 |
# Project-wide settings |
| 32 |
|
| 33 |
# Name of the project. |
| 34 |
# |
| 35 |
# CMake files in this project can refer to the root source directory |
| 36 |
# as ${gmock_SOURCE_DIR} and to the root binary directory as |
| 37 |
# ${gmock_BINARY_DIR}. |
| 38 |
# Language "C" is required for find_package(Threads). |
| 39 |
cmake_minimum_required(VERSION 3.5) |
| 40 |
cmake_policy(SET CMP0048 NEW) |
| 41 |
project(gmock VERSION ${GOOGLETEST_VERSION} LANGUAGES CXX C) |
| 42 |
|
| 43 |
if (COMMAND set_up_hermetic_build) |
| 44 |
set_up_hermetic_build() |
| 45 |
endif() |
| 46 |
|
| 47 |
# Instructs CMake to process Google Test's CMakeLists.txt and add its |
| 48 |
# targets to the current scope. We are placing Google Test's binary |
| 49 |
# directory in a subdirectory of our own as VC compilation may break |
| 50 |
# if they are the same (the default). |
| 51 |
add_subdirectory("${gtest_dir}" "${gmock_BINARY_DIR}/${gtest_dir}") |
| 52 |
|
| 53 |
|
| 54 |
# These commands only run if this is the main project |
| 55 |
if(CMAKE_PROJECT_NAME STREQUAL "gmock" OR CMAKE_PROJECT_NAME STREQUAL "googletest-distribution") |
| 56 |
# BUILD_SHARED_LIBS is a standard CMake variable, but we declare it here to |
| 57 |
# make it prominent in the GUI. |
| 58 |
option(BUILD_SHARED_LIBS "Build shared libraries (DLLs)." OFF) |
| 59 |
else() |
| 60 |
mark_as_advanced(gmock_build_tests) |
| 61 |
endif() |
| 62 |
|
| 63 |
# Although Google Test's CMakeLists.txt calls this function, the |
| 64 |
# changes there don't affect the current scope. Therefore we have to |
| 65 |
# call it again here. |
| 66 |
config_compiler_and_linker() # from ${gtest_dir}/cmake/internal_utils.cmake |
| 67 |
|
| 68 |
# Adds Google Mock's and Google Test's header directories to the search path. |
| 69 |
set(gmock_build_include_dirs |
| 70 |
"${gmock_SOURCE_DIR}/include" |
| 71 |
"${gmock_SOURCE_DIR}" |
| 72 |
"${gtest_SOURCE_DIR}/include" |
| 73 |
# This directory is needed to build directly from Google Test sources. |
| 74 |
"${gtest_SOURCE_DIR}") |
| 75 |
include_directories(${gmock_build_include_dirs}) |
| 76 |
|
| 77 |
######################################################################## |
| 78 |
# |
| 79 |
# Defines the gmock & gmock_main libraries. User tests should link |
| 80 |
# with one of them. |
| 81 |
|
| 82 |
# Google Mock libraries. We build them using more strict warnings than what |
| 83 |
# are used for other targets, to ensure that Google Mock can be compiled by |
| 84 |
# a user aggressive about warnings. |
| 85 |
if (MSVC) |
| 86 |
cxx_library(gmock |
| 87 |
"${cxx_strict}" |
| 88 |
"${gtest_dir}/src/gtest-all.cc" |
| 89 |
src/gmock-all.cc) |
| 90 |
|
| 91 |
cxx_library(gmock_main |
| 92 |
"${cxx_strict}" |
| 93 |
"${gtest_dir}/src/gtest-all.cc" |
| 94 |
src/gmock-all.cc |
| 95 |
src/gmock_main.cc) |
| 96 |
else() |
| 97 |
cxx_library(gmock "${cxx_strict}" src/gmock-all.cc) |
| 98 |
target_link_libraries(gmock PUBLIC gtest) |
| 99 |
set_target_properties(gmock PROPERTIES VERSION ${GOOGLETEST_VERSION}) |
| 100 |
cxx_library(gmock_main "${cxx_strict}" src/gmock_main.cc) |
| 101 |
target_link_libraries(gmock_main PUBLIC gmock) |
| 102 |
set_target_properties(gmock_main PROPERTIES VERSION ${GOOGLETEST_VERSION}) |
| 103 |
endif() |
| 104 |
# If the CMake version supports it, attach header directory information |
| 105 |
# to the targets for when we are part of a parent build (ie being pulled |
| 106 |
# in via add_subdirectory() rather than being a standalone build). |
| 107 |
if (DEFINED CMAKE_VERSION AND NOT "${CMAKE_VERSION}" VERSION_LESS "2.8.11") |
| 108 |
target_include_directories(gmock SYSTEM INTERFACE |
| 109 |
"$<BUILD_INTERFACE:${gmock_build_include_dirs}>" |
| 110 |
"$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>") |
| 111 |
target_include_directories(gmock_main SYSTEM INTERFACE |
| 112 |
"$<BUILD_INTERFACE:${gmock_build_include_dirs}>" |
| 113 |
"$<INSTALL_INTERFACE:$<INSTALL_PREFIX>/${CMAKE_INSTALL_INCLUDEDIR}>") |
| 114 |
endif() |
| 115 |
|
| 116 |
######################################################################## |
| 117 |
# |
| 118 |
# Install rules |
| 119 |
install_project(gmock gmock_main) |
| 120 |
|
| 121 |
######################################################################## |
| 122 |
# |
| 123 |
# Google Mock's own tests. |
| 124 |
# |
| 125 |
# You can skip this section if you aren't interested in testing |
| 126 |
# Google Mock itself. |
| 127 |
# |
| 128 |
# The tests are not built by default. To build them, set the |
| 129 |
# gmock_build_tests option to ON. You can do it by running ccmake |
| 130 |
# or specifying the -Dgmock_build_tests=ON flag when running cmake. |
| 131 |
|
| 132 |
if (gmock_build_tests) |
| 133 |
# This must be set in the root directory for the tests to be run by |
| 134 |
# 'make test' or ctest. |
| 135 |
enable_testing() |
| 136 |
|
| 137 |
if (MINGW OR CYGWIN) |
| 138 |
if (CMAKE_VERSION VERSION_LESS "2.8.12") |
| 139 |
add_compile_options("-Wa,-mbig-obj") |
| 140 |
else() |
| 141 |
add_definitions("-Wa,-mbig-obj") |
| 142 |
endif() |
| 143 |
endif() |
| 144 |
|
| 145 |
############################################################ |
| 146 |
# C++ tests built with standard compiler flags. |
| 147 |
|
| 148 |
cxx_test(gmock-actions_test gmock_main) |
| 149 |
cxx_test(gmock-cardinalities_test gmock_main) |
| 150 |
cxx_test(gmock_ex_test gmock_main) |
| 151 |
cxx_test(gmock-function-mocker_test gmock_main) |
| 152 |
cxx_test(gmock-internal-utils_test gmock_main) |
| 153 |
cxx_test(gmock-matchers_test gmock_main) |
| 154 |
cxx_test(gmock-more-actions_test gmock_main) |
| 155 |
cxx_test(gmock-nice-strict_test gmock_main) |
| 156 |
cxx_test(gmock-port_test gmock_main) |
| 157 |
cxx_test(gmock-spec-builders_test gmock_main) |
| 158 |
cxx_test(gmock_link_test gmock_main test/gmock_link2_test.cc) |
| 159 |
cxx_test(gmock_test gmock_main) |
| 160 |
|
| 161 |
if (DEFINED GTEST_HAS_PTHREAD) |
| 162 |
cxx_test(gmock_stress_test gmock) |
| 163 |
endif() |
| 164 |
|
| 165 |
# gmock_all_test is commented to save time building and running tests. |
| 166 |
# Uncomment if necessary. |
| 167 |
# cxx_test(gmock_all_test gmock_main) |
| 168 |
|
| 169 |
############################################################ |
| 170 |
# C++ tests built with non-standard compiler flags. |
| 171 |
|
| 172 |
if (MSVC) |
| 173 |
cxx_library(gmock_main_no_exception "${cxx_no_exception}" |
| 174 |
"${gtest_dir}/src/gtest-all.cc" src/gmock-all.cc src/gmock_main.cc) |
| 175 |
|
| 176 |
cxx_library(gmock_main_no_rtti "${cxx_no_rtti}" |
| 177 |
"${gtest_dir}/src/gtest-all.cc" src/gmock-all.cc src/gmock_main.cc) |
| 178 |
|
| 179 |
else() |
| 180 |
cxx_library(gmock_main_no_exception "${cxx_no_exception}" src/gmock_main.cc) |
| 181 |
target_link_libraries(gmock_main_no_exception PUBLIC gmock) |
| 182 |
|
| 183 |
cxx_library(gmock_main_no_rtti "${cxx_no_rtti}" src/gmock_main.cc) |
| 184 |
target_link_libraries(gmock_main_no_rtti PUBLIC gmock) |
| 185 |
endif() |
| 186 |
cxx_test_with_flags(gmock-more-actions_no_exception_test "${cxx_no_exception}" |
| 187 |
gmock_main_no_exception test/gmock-more-actions_test.cc) |
| 188 |
|
| 189 |
cxx_test_with_flags(gmock_no_rtti_test "${cxx_no_rtti}" |
| 190 |
gmock_main_no_rtti test/gmock-spec-builders_test.cc) |
| 191 |
|
| 192 |
cxx_shared_library(shared_gmock_main "${cxx_default}" |
| 193 |
"${gtest_dir}/src/gtest-all.cc" src/gmock-all.cc src/gmock_main.cc) |
| 194 |
|
| 195 |
# Tests that a binary can be built with Google Mock as a shared library. On |
| 196 |
# some system configurations, it may not possible to run the binary without |
| 197 |
# knowing more details about the system configurations. We do not try to run |
| 198 |
# this binary. To get a more robust shared library coverage, configure with |
| 199 |
# -DBUILD_SHARED_LIBS=ON. |
| 200 |
cxx_executable_with_flags(shared_gmock_test_ "${cxx_default}" |
| 201 |
shared_gmock_main test/gmock-spec-builders_test.cc) |
| 202 |
set_target_properties(shared_gmock_test_ |
| 203 |
PROPERTIES |
| 204 |
COMPILE_DEFINITIONS "GTEST_LINKED_AS_SHARED_LIBRARY=1") |
| 205 |
|
| 206 |
############################################################ |
| 207 |
# Python tests. |
| 208 |
|
| 209 |
cxx_executable(gmock_leak_test_ test gmock_main) |
| 210 |
py_test(gmock_leak_test) |
| 211 |
|
| 212 |
cxx_executable(gmock_output_test_ test gmock) |
| 213 |
py_test(gmock_output_test) |
| 214 |
endif() |