Debian Codegraph @

libraries/Wire/examples/i2c_scanner/i2c_scanner.ino

raw
1 // --------------------------------------
2 // i2c_scanner
3 //
4 // Version 1
5 // This program (or code that looks like it)
6 // can be found in many places.
7 // For example on the Arduino.cc forum.
8 // The original author is not known.
9 // Version 2, June 2012, Using Arduino 1.0.1
10 // Adapted to be as simple as possible by Arduino.cc user Krodal
11 // Version 3, Feb 26 2013
12 // V3 by louarnold
13 // Version 4, March 3, 2013, Using Arduino 1.0.3
14 // by Arduino.cc user Krodal.
15 // Changes by louarnold removed.
16 // Scanning addresses changed from 0...127 to 1...119,
17 // according to the i2c scanner by Nick Gammon
18 // https://www.gammon.com.au/forum/?id=10896
19 // Version 5, March 28, 2013
20 // As version 4, but address scans now to 127.
21 // A sensor seems to use address 120.
22 // Version 6, November 27, 2015.
23 // Added waiting for the Leonardo serial communication.
24 //
25 //
26 // This sketch tests the standard 7-bit addresses
27 // Devices with higher bit address might not be seen properly.
28 //
29
30 #include <Wire.h>
31
32 void setup() {
33 Wire.begin();
34
35 Serial.begin(9600);
36 while (!Serial); // Leonardo: wait for Serial Monitor
37 Serial.println("\nI2C Scanner");
38 }
39
40 void loop() {
41 int nDevices = 0;
42
43 Serial.println("Scanning...");
44
45 for (byte address = 1; address < 127; ++address) {
46 // The i2c_scanner uses the return value of
47 // the Wire.endTransmission to see if
48 // a device did acknowledge to the address.
49 Wire.beginTransmission(address);
50 byte error = Wire.endTransmission();
51
52 if (error == 0) {
53 Serial.print("I2C device found at address 0x");
54 if (address < 16) {
55 Serial.print("0");
56 }
57 Serial.print(address, HEX);
58 Serial.println(" !");
59
60 ++nDevices;
61 } else if (error == 4) {
62 Serial.print("Unknown error at address 0x");
63 if (address < 16) {
64 Serial.print("0");
65 }
66 Serial.println(address, HEX);
67 }
68 }
69 if (nDevices == 0) {
70 Serial.println("No I2C devices found\n");
71 } else {
72 Serial.println("done\n");
73 }
74 delay(5000); // Wait 5 seconds for next scan
75 }