Debian Codegraph @

build/m4/ax_check_openssl.m4

raw
1 # ===========================================================================
2 # https://www.gnu.org/software/autoconf-archive/ax_check_openssl.html
3 # ===========================================================================
4 #
5 # SYNOPSIS
6 #
7 # AX_CHECK_OPENSSL([action-if-found[, action-if-not-found]])
8 #
9 # DESCRIPTION
10 #
11 # Look for OpenSSL in a number of default spots, or in a user-selected
12 # spot (via --with-openssl). Sets
13 #
14 # OPENSSL_INCLUDES to the include directives required
15 # OPENSSL_LIBS to the -l directives required
16 # OPENSSL_LDFLAGS to the -L or -R flags required
17 #
18 # and calls ACTION-IF-FOUND or ACTION-IF-NOT-FOUND appropriately
19 #
20 # This macro sets OPENSSL_INCLUDES such that source files should use the
21 # openssl/ directory in include directives:
22 #
23 # #include <openssl/hmac.h>
24 #
25 # LICENSE
26 #
27 # Copyright (c) 2009,2010 Zmanda Inc. <http://www.zmanda.com/>
28 # Copyright (c) 2009,2010 Dustin J. Mitchell <[email protected]>
29 #
30 # Copying and distribution of this file, with or without modification, are
31 # permitted in any medium without royalty provided the copyright notice
32 # and this notice are preserved. This file is offered as-is, without any
33 # warranty.
34
35 #serial 10
36
37 AU_ALIAS([CHECK_SSL], [AX_CHECK_OPENSSL])
38 AC_DEFUN([AX_CHECK_OPENSSL], [
39 found=false
40 AC_ARG_WITH([openssl],
41 [AS_HELP_STRING([--with-openssl=DIR],
42 [root of the OpenSSL directory])],
43 [
44 case "$withval" in
45 "" | y | ye | yes | n | no)
46 AC_MSG_ERROR([Invalid --with-openssl value])
47 ;;
48 *) ssldirs="$withval"
49 ;;
50 esac
51 ], [
52 AC_CHECK_LIB([crypto], [OPENSSL_init], [
53 OPENSSL_LIBS="-lssl -lcrypto"
54 OPENSSL_LDFLAGS=""
55
56 AC_CHECK_HEADERS([openssl/crypto.h], [
57 OPENSSL_INCLUDES=""
58 found=true
59 ])
60 ])
61
62 if ! $found; then
63 # if pkg-config is installed and openssl has installed a .pc file,
64 # then use that information and don't search ssldirs
65 AC_CHECK_TOOL([PKG_CONFIG], [pkg-config])
66 if test x"$PKG_CONFIG" != x""; then
67 OPENSSL_LDFLAGS=`$PKG_CONFIG openssl --libs-only-L 2>/dev/null`
68 if test $? = 0; then
69 OPENSSL_LIBS=`$PKG_CONFIG openssl --libs-only-l 2>/dev/null`
70 OPENSSL_INCLUDES=`$PKG_CONFIG openssl --cflags-only-I 2>/dev/null`
71 found=true
72 fi
73 fi
74 fi
75
76 # no such luck; use some default ssldirs
77 if ! $found; then
78 ssldirs="/usr/local/ssl /usr/lib/ssl /usr/ssl /usr/pkg /usr/local /usr"
79 fi
80 ]
81 )
82
83
84 # note that we #include <openssl/foo.h>, so the OpenSSL headers have to be in
85 # an 'openssl' subdirectory
86
87 if ! $found; then
88 OPENSSL_INCLUDES=
89 for ssldir in $ssldirs; do
90 AC_MSG_CHECKING([for openssl/ssl.h in $ssldir])
91 if test -f "$ssldir/include/openssl/ssl.h"; then
92 OPENSSL_INCLUDES="-I$ssldir/include"
93 OPENSSL_LDFLAGS="-L$ssldir/lib"
94 OPENSSL_LIBS="-lssl -lcrypto"
95 found=true
96 AC_MSG_RESULT([yes])
97 break
98 else
99 AC_MSG_RESULT([no])
100 fi
101 done
102
103 # if the file wasn't found, well, go ahead and try the link anyway -- maybe
104 # it will just work!
105 fi
106
107 # try the preprocessor and linker with our new flags,
108 # being careful not to pollute the global LIBS, LDFLAGS, and CPPFLAGS
109
110 AC_MSG_CHECKING([whether compiling and linking against OpenSSL works])
111 echo "Trying link with OPENSSL_LDFLAGS=$OPENSSL_LDFLAGS;" \
112 "OPENSSL_LIBS=$OPENSSL_LIBS; OPENSSL_INCLUDES=$OPENSSL_INCLUDES" >&AS_MESSAGE_LOG_FD
113
114 save_LIBS="$LIBS"
115 save_LDFLAGS="$LDFLAGS"
116 save_CPPFLAGS="$CPPFLAGS"
117 LDFLAGS="$LDFLAGS $OPENSSL_LDFLAGS"
118 LIBS="$OPENSSL_LIBS $LIBS"
119 CPPFLAGS="$OPENSSL_INCLUDES $CPPFLAGS"
120 AC_LINK_IFELSE(
121 [AC_LANG_PROGRAM([#include <openssl/ssl.h>], [SSL_new(NULL)])],
122 [
123 AC_MSG_RESULT([yes])
124 $1
125 ], [
126 AC_MSG_RESULT([no])
127 $2
128 ])
129 CPPFLAGS="$save_CPPFLAGS"
130 LDFLAGS="$save_LDFLAGS"
131 LIBS="$save_LIBS"
132
133 AC_SUBST([OPENSSL_INCLUDES])
134 AC_SUBST([OPENSSL_LIBS])
135 AC_SUBST([OPENSSL_LDFLAGS])
136 ])