Debian Codegraph @

build_files/Modules/FindOpenEXR.cmake

raw ◀ ▶
Source reconstructed at patch state 0 of 1 — not the installed (fully patched) source.
1 Debian patch touch this file
1 # - Find OpenEXR library
2 # Find the native OpenEXR includes and library
3 # This module defines
4 # OPENEXR_INCLUDE_DIRS, where to find ImfXdr.h, etc. Set when
5 # OPENEXR_INCLUDE_DIR is found.
6 # OPENEXR_LIBRARIES, libraries to link against to use OpenEXR.
7 # OPENEXR_ROOT_DIR, The base directory to search for OpenEXR.
8 # This can also be an environment variable.
9 # OPENEXR_FOUND, If false, do not try to use OpenEXR.
10 #
11 # For individual library access these advanced settings are available
12 # OPENEXR_HALF_LIBRARY, Path to Half library
13 # OPENEXR_IEX_LIBRARY, Path to Half library
14 # OPENEXR_ILMIMF_LIBRARY, Path to Ilmimf library
15 # OPENEXR_ILMTHREAD_LIBRARY, Path to IlmThread library
16 # OPENEXR_IMATH_LIBRARY, Path to Imath library
17 #
18 # also defined, but not for general use are
19 # OPENEXR_LIBRARY, where to find the OpenEXR library.
20
21 #=============================================================================
22 # Copyright 2011 Blender Foundation.
23 #
24 # Distributed under the OSI-approved BSD License (the "License");
25 # see accompanying file Copyright.txt for details.
26 #
27 # This software is distributed WITHOUT ANY WARRANTY; without even the
28 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
29 # See the License for more information.
30 #=============================================================================
31
32 # If OPENEXR_ROOT_DIR was defined in the environment, use it.
33 IF(NOT OPENEXR_ROOT_DIR AND NOT $ENV{OPENEXR_ROOT_DIR} STREQUAL "")
34 SET(OPENEXR_ROOT_DIR $ENV{OPENEXR_ROOT_DIR})
35 ENDIF()
36
37 if (NOT OPENEXR_VERSION)
38 SET(OPENEXR_VERSION "2.0.1")
39 endif()
40 if (${OPENEXR_VERSION} VERSION_LESS "2.1")
41 SET(_openexr_FIND_COMPONENTS
42 Half
43 Iex
44 IlmImf
45 IlmThread
46 Imath
47 )
48 else ()
49 string(REGEX REPLACE "([0-9]+)[.]([0-9]+).*" "\\1_\\2" _openexr_libs_ver ${OPENEXR_VERSION})
50 SET(_openexr_FIND_COMPONENTS
51 Half
52 Iex-${_openexr_libs_ver}
53 IlmImf-${_openexr_libs_ver}
54 IlmThread-${_openexr_libs_ver}
55 Imath-${_openexr_libs_ver}
56 )
57 endif ()
58
59 SET(_openexr_SEARCH_DIRS
60 ${OPENEXR_ROOT_DIR}
61 /usr/local
62 /sw # Fink
63 /opt/local # DarwinPorts
64 /opt/csw # Blastwave
65 )
66
67 FIND_PATH(OPENEXR_INCLUDE_DIR
68 NAMES
69 OpenEXR/ImfXdr.h
70 HINTS
71 ${_openexr_SEARCH_DIRS}
72 PATH_SUFFIXES
73 include
74 )
75
76 SET(_openexr_LIBRARIES)
77 FOREACH(COMPONENT ${_openexr_FIND_COMPONENTS})
78 STRING(TOUPPER ${COMPONENT} UPPERCOMPONENT)
79
80 FIND_LIBRARY(OPENEXR_${UPPERCOMPONENT}_LIBRARY
81 NAMES
82 ${COMPONENT}
83 HINTS
84 ${_openexr_SEARCH_DIRS}
85 PATH_SUFFIXES
86 lib64 lib
87 )
88 LIST(APPEND _openexr_LIBRARIES "${OPENEXR_${UPPERCOMPONENT}_LIBRARY}")
89 ENDFOREACH()
90
91 # handle the QUIETLY and REQUIRED arguments and set OPENEXR_FOUND to TRUE if
92 # all listed variables are TRUE
93 INCLUDE(FindPackageHandleStandardArgs)
94 FIND_PACKAGE_HANDLE_STANDARD_ARGS(OpenEXR DEFAULT_MSG
95 _openexr_LIBRARIES OPENEXR_INCLUDE_DIR)
96
97 IF(OPENEXR_FOUND)
98 SET(OPENEXR_LIBRARIES ${_openexr_LIBRARIES})
99 # Both include paths are needed because of dummy OSL headers mixing #include <OpenEXR/foo.h> and #include <foo.h> :(
100 SET(OPENEXR_INCLUDE_DIRS ${OPENEXR_INCLUDE_DIR} ${OPENEXR_INCLUDE_DIR}/OpenEXR)
101 message(STATUS "OpenEXR found")
102 ENDIF()
103
104 MARK_AS_ADVANCED(OPENEXR_INCLUDE_DIR)
105 FOREACH(COMPONENT ${_openexr_FIND_COMPONENTS})
106 STRING(TOUPPER ${COMPONENT} UPPERCOMPONENT)
107 MARK_AS_ADVANCED(OPENEXR_${UPPERCOMPONENT}_LIBRARY)
108 ENDFOREACH()