Debian Codegraph @

CMakeLists.txt

raw ◀ ▶
Source reconstructed at patch state 0 of 3 — not the installed (fully patched) source.
3 Debian patches touch this file
1 cmake_minimum_required (VERSION 3.16)
2 project (glog
3 VERSION 0.6.0
4 DESCRIPTION "C++ implementation of the Google logging module"
5 HOMEPAGE_URL https://github.com/google/glog
6 LANGUAGES CXX
7 )
8
9 set (CPACK_PACKAGE_NAME glog)
10 set (CPACK_PACKAGE_DESCRIPTION_SUMMARY "Google logging library")
11 set (CPACK_PACKAGE_VERSION_MAJOR ${PROJECT_VERSION_MAJOR})
12 set (CPACK_PACKAGE_VERSION_MINOR ${PROJECT_VERSION_MINOR})
13 set (CPACK_PACKAGE_VERSION_PATCH ${PROJECT_VERSION_PATCH})
14 set (CPACK_PACKAGE_VERSION ${PROJECT_VERSION})
15
16 list (APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
17
18 include (CheckCXXCompilerFlag)
19 include (CheckCXXSourceCompiles)
20 include (CheckCXXSourceRuns)
21 include (CheckCXXSymbolExists)
22 include (CheckFunctionExists)
23 include (CheckIncludeFileCXX)
24 include (CheckLibraryExists)
25 include (CheckStructHasMember)
26 include (CheckTypeSize)
27 include (CMakeDependentOption)
28 include (CMakePackageConfigHelpers)
29 include (CMakePushCheckState)
30 include (CPack)
31 include (CTest)
32 include (DetermineGflagsNamespace)
33 include (GenerateExportHeader)
34 include (GetCacheVariables)
35 include (GNUInstallDirs)
36
37 option (BUILD_SHARED_LIBS "Build shared libraries" ON)
38 option (PRINT_UNSYMBOLIZED_STACK_TRACES
39 "Print file offsets in traces instead of symbolizing" OFF)
40 option (WITH_CUSTOM_PREFIX "Enable support for user-generated message prefixes" ON)
41 option (WITH_GFLAGS "Use gflags" ON)
42 option (WITH_GTEST "Use Google Test" ON)
43 option (WITH_PKGCONFIG "Enable pkg-config support" ON)
44 option (WITH_SYMBOLIZE "Enable symbolize module" ON)
45 option (WITH_THREADS "Enable multithreading support" ON)
46 option (WITH_TLS "Enable Thread Local Storage (TLS) support" ON)
47 option (WITH_UNWIND "Enable libunwind support" ON)
48
49 cmake_dependent_option (WITH_GMOCK "Use Google Mock" ON WITH_GTEST OFF)
50
51 if (NOT WITH_UNWIND)
52 set (CMAKE_DISABLE_FIND_PACKAGE_Unwind ON)
53 endif (NOT WITH_UNWIND)
54
55 if (NOT WITH_GTEST)
56 set (CMAKE_DISABLE_FIND_PACKAGE_GTest ON)
57 endif (NOT WITH_GTEST)
58
59 if (NOT WITH_THREADS)
60 set (CMAKE_DISABLE_FIND_PACKAGE_Threads ON)
61 endif (NOT WITH_THREADS)
62
63 set (CMAKE_C_VISIBILITY_PRESET hidden)
64 set (CMAKE_CXX_VISIBILITY_PRESET hidden)
65 set (CMAKE_POSITION_INDEPENDENT_CODE ON)
66 set (CMAKE_VISIBILITY_INLINES_HIDDEN ON)
67
68 set (CMAKE_DEBUG_POSTFIX d)
69 set (CMAKE_THREAD_PREFER_PTHREAD 1)
70
71 find_package (GTest NO_MODULE)
72
73 if (GTest_FOUND)
74 set (HAVE_LIB_GTEST 1)
75 endif (GTest_FOUND)
76
77 if (WITH_GMOCK AND TARGET GTest::gmock)
78 set (HAVE_LIB_GMOCK 1)
79 endif (WITH_GMOCK AND TARGET GTest::gmock)
80
81 if (WITH_GFLAGS)
82 find_package (gflags 2.2.2)
83
84 if (gflags_FOUND)
85 set (HAVE_LIB_GFLAGS 1)
86 determine_gflags_namespace (gflags_NAMESPACE)
87 endif (gflags_FOUND)
88 endif (WITH_GFLAGS)
89
90 find_package (Threads)
91 find_package (Unwind)
92
93 if (Unwind_FOUND)
94 set (HAVE_LIB_UNWIND 1)
95 else (Unwind_FOUND)
96 check_include_file_cxx (unwind.h HAVE_UNWIND_H)
97 # Check whether linking actually succeeds. ARM toolchains of LLVM unwind
98 # implementation do not necessarily provide the _Unwind_Backtrace function
99 # which causes the previous check to succeed but the linking to fail.
100 check_cxx_symbol_exists (_Unwind_Backtrace unwind.h HAVE__UNWIND_BACKTRACE)
101 endif (Unwind_FOUND)
102
103 check_include_file_cxx (dlfcn.h HAVE_DLFCN_H)
104 check_include_file_cxx (execinfo.h HAVE_EXECINFO_H)
105 check_include_file_cxx (glob.h HAVE_GLOB_H)
106 check_include_file_cxx (inttypes.h HAVE_INTTYPES_H)
107 check_include_file_cxx (memory.h HAVE_MEMORY_H)
108 check_include_file_cxx (pwd.h HAVE_PWD_H)
109 check_include_file_cxx (stdint.h HAVE_STDINT_H)
110 check_include_file_cxx (strings.h HAVE_STRINGS_H)
111 check_include_file_cxx (sys/stat.h HAVE_SYS_STAT_H)
112 check_include_file_cxx (sys/syscall.h HAVE_SYS_SYSCALL_H)
113 check_include_file_cxx (sys/time.h HAVE_SYS_TIME_H)
114 check_include_file_cxx (sys/types.h HAVE_SYS_TYPES_H)
115 check_include_file_cxx (sys/utsname.h HAVE_SYS_UTSNAME_H)
116 check_include_file_cxx (sys/wait.h HAVE_SYS_WAIT_H)
117 check_include_file_cxx (syscall.h HAVE_SYSCALL_H)
118 check_include_file_cxx (syslog.h HAVE_SYSLOG_H)
119 check_include_file_cxx (ucontext.h HAVE_UCONTEXT_H)
120 check_include_file_cxx (unistd.h HAVE_UNISTD_H)
121
122 check_include_file_cxx ("ext/hash_map" HAVE_EXT_HASH_MAP)
123 check_include_file_cxx ("ext/hash_set" HAVE_EXT_HASH_SET)
124 check_include_file_cxx ("ext/slist" HAVE_EXT_SLIST)
125 check_include_file_cxx ("tr1/unordered_map" HAVE_TR1_UNORDERED_MAP)
126 check_include_file_cxx ("tr1/unordered_set" HAVE_TR1_UNORDERED_SET)
127 check_include_file_cxx ("unordered_map" HAVE_UNORDERED_MAP)
128 check_include_file_cxx ("unordered_set" HAVE_UNORDERED_SET)
129
130 check_type_size ("unsigned __int16" HAVE___UINT16 LANGUAGE CXX)
131 check_type_size (u_int16_t HAVE_U_INT16_T LANGUAGE CXX)
132 check_type_size (uint16_t HAVE_UINT16_T LANGUAGE CXX)
133
134 check_function_exists (dladdr HAVE_DLADDR)
135 check_function_exists (fcntl HAVE_FCNTL)
136 check_function_exists (pread HAVE_PREAD)
137 check_function_exists (pwrite HAVE_PWRITE)
138 check_function_exists (sigaction HAVE_SIGACTION)
139 check_function_exists (sigaltstack HAVE_SIGALTSTACK)
140
141 # NOTE gcc does not fail if you pass a non-existent -Wno-* option as an
142 # argument. However, it will happily fail if you pass the corresponding -W*
143 # option. So, we check whether options that disable warnings exist by testing
144 # the availability of the corresponding option that enables the warning. This
145 # eliminates the need to check for compiler for several (mainly Clang) options.
146
147 check_cxx_compiler_flag (-Wdeprecated HAVE_NO_DEPRECATED)
148 check_cxx_compiler_flag (-Wunnamed-type-template-args
149 HAVE_NO_UNNAMED_TYPE_TEMPLATE_ARGS)
150
151 cmake_push_check_state (RESET)
152
153 if (Threads_FOUND)
154 set (CMAKE_REQUIRED_LIBRARIES Threads::Threads)
155 endif (Threads_FOUND)
156
157 check_cxx_symbol_exists (pthread_threadid_np "pthread.h" HAVE_PTHREAD_THREADID_NP)
158 cmake_pop_check_state ()
159
160 # NOTE: Cannot use check_function_exists here since >=vc-14.0 can define
161 # snprintf as an inline function
162 check_cxx_symbol_exists (snprintf cstdio HAVE_SNPRINTF)
163
164 check_library_exists (dbghelp UnDecorateSymbolName "" HAVE_DBGHELP)
165
166 check_cxx_source_compiles ("
167 #include <cstdlib>
168 static void foo(void) __attribute__ ((unused));
169 int main(void) { return 0; }
170 " HAVE___ATTRIBUTE__)
171
172 check_cxx_source_compiles ("
173 #include <cstdlib>
174 static void foo(void) __attribute__ ((visibility(\"default\")));
175 int main(void) { return 0; }
176 " HAVE___ATTRIBUTE__VISIBILITY_DEFAULT)
177
178 check_cxx_source_compiles ("
179 #include <cstdlib>
180 static void foo(void) __attribute__ ((visibility(\"hidden\")));
181 int main(void) { return 0; }
182 " HAVE___ATTRIBUTE__VISIBILITY_HIDDEN)
183
184 check_cxx_source_compiles ("
185 int main(void) { if (__builtin_expect(0, 0)) return 1; return 0; }
186 " HAVE___BUILTIN_EXPECT)
187
188 check_cxx_source_compiles ("
189 int main(void)
190 {
191 int a; if (__sync_val_compare_and_swap(&a, 0, 1)) return 1; return 0;
192 }
193 " HAVE___SYNC_VAL_COMPARE_AND_SWAP)
194
195 cmake_push_check_state (RESET)
196 set (CMAKE_REQUIRED_LIBRARIES Threads::Threads)
197 check_cxx_source_compiles ("
198 #define _XOPEN_SOURCE 500
199 #include <pthread.h>
200 int main(void)
201 {
202 pthread_rwlock_t l;
203 pthread_rwlock_init(&l, NULL);
204 pthread_rwlock_rdlock(&l);
205 return 0;
206 }
207 " HAVE_RWLOCK)
208 cmake_pop_check_state ()
209
210 check_cxx_source_compiles ("
211 __declspec(selectany) int a;
212 int main(void) { return 0; }
213 " HAVE___DECLSPEC)
214
215 check_cxx_source_compiles ("
216 #include <vector>
217 vector<int> t; int main() { }
218 " STL_NO_NAMESPACE)
219
220 check_cxx_source_compiles ("
221 #include <vector>
222 std::vector<int> t; int main() { }
223 " STL_STD_NAMESPACE)
224
225 check_cxx_source_compiles ("
226 #include <iostream>
227 std::ostream& operator<<(std::ostream&, struct s);
228 using ::operator<<;
229 int main() { }
230 " HAVE_USING_OPERATOR)
231
232 check_cxx_source_compiles ("
233 namespace Outer { namespace Inner { int i = 0; }}
234 using namespace Outer::Inner;;
235 int main() { return i; }
236 " HAVE_NAMESPACES)
237
238 check_cxx_source_compiles ("
239 __thread int tls;
240 int main() { }
241 " HAVE_GCC_TLS)
242
243 check_cxx_source_compiles ("
244 __declspec(thread) int tls;
245 int main() { }
246 " HAVE_MSVC_TLS)
247
248 check_cxx_source_compiles ("
249 thread_local int tls;
250 int main() { }
251 " HAVE_CXX11_TLS)
252
253 check_cxx_source_compiles ("
254 #include <type_traits>
255 std::aligned_storage<sizeof(char), alignof(char)>::type data;
256 int main() { }
257 " HAVE_ALIGNED_STORAGE)
258
259 check_cxx_source_compiles ("
260 #include <atomic>
261 std::atomic<int> i;
262 int main() { }
263 " HAVE_CXX11_ATOMIC)
264
265 check_cxx_source_compiles ("
266 constexpr int x = 0;
267 int main() { }
268 " HAVE_CXX11_CONSTEXPR)
269
270 check_cxx_source_compiles ("
271 #include <chrono>
272 std::chrono::seconds s;
273 int main() { }
274 " HAVE_CXX11_CHRONO)
275
276 check_cxx_source_compiles ("
277 #include <cstddef>
278 void foo(std::nullptr_t) {}
279 int main(void) { foo(nullptr); }
280 " HAVE_CXX11_NULLPTR_T)
281
282 if (WITH_TLS)
283 # Cygwin does not support the thread attribute. Don't bother.
284 if (HAVE_GCC_TLS)
285 set (GLOG_THREAD_LOCAL_STORAGE "__thread")
286 elseif (HAVE_MSVC_TLS)
287 set (GLOG_THREAD_LOCAL_STORAGE "__declspec(thread)")
288 elseif (HAVE_CXX11_TLS)
289 set (GLOG_THREAD_LOCAL_STORAGE thread_local)
290 endif (HAVE_GCC_TLS)
291 endif (WITH_TLS)
292
293 set (_PC_FIELDS
294 "gregs[REG_PC]"
295 "gregs[REG_EIP]"
296 "gregs[REG_RIP]"
297 "sc_ip"
298 "uc_regs->gregs[PT_NIP]"
299 "gregs[R15]"
300 "arm_pc"
301 "mc_eip"
302 "mc_rip"
303 "__gregs[REG_EIP]"
304 "__gregs[REG_RIP]"
305 "ss.eip"
306 "__ss.__eip"
307 "ss.rip"
308 "__ss.__rip"
309 "ss.srr0"
310 "__ss.__srr0"
311 )
312
313 set (_PC_HEADERS ucontext.h signal.h)
314
315 if (HAVE_UCONTEXT_H AND NOT PC_FROM_UCONTEXT)
316 foreach (_PC_FIELD ${_PC_FIELDS})
317 foreach (_PC_HEADER ${_PC_HEADERS})
318 set (_TMP
319 ${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/uctfield.cpp)
320 file (WRITE ${_TMP} "
321 #define _GNU_SOURCE 1
322 #include <${_PC_HEADER}>
323 int main(void)
324 {
325 ucontext_t u;
326 return u.${_PC_FIELD} == 0;
327 }
328 ")
329 try_compile (HAVE_PC_FROM_UCONTEXT ${CMAKE_CURRENT_BINARY_DIR} ${_TMP}
330 COMPILE_DEFINITIONS _GNU_SOURCE=1)
331
332 if (HAVE_PC_FROM_UCONTEXT)
333 set (PC_FROM_UCONTEXT ${_PC_FIELD} CACHE)
334 endif (HAVE_PC_FROM_UCONTEXT)
335 endforeach (_PC_HEADER)
336 endforeach (_PC_FIELD)
337 endif (HAVE_UCONTEXT_H AND NOT PC_FROM_UCONTEXT)
338
339 if (STL_STD_NAMESPACE)
340 set (STL_NAMESPACE std)
341 else (STL_STD_NAMESPACE)
342 set (STL_NAMESPACE "")
343 endif (STL_STD_NAMESPACE)
344
345 set (GOOGLE_NAMESPACE google)
346 set (_START_GOOGLE_NAMESPACE_ "namespace ${GOOGLE_NAMESPACE} {")
347 set (_END_GOOGLE_NAMESPACE_ "}")
348 set (ac_cv_have_glog_export 1)
349
350 if (HAVE___UINT16)
351 set (ac_cv_have___uint16 1)
352 else (HAVE___UINT16)
353 set (ac_cv_have___uint16 0)
354 endif (HAVE___UINT16)
355
356 if (HAVE_INTTYPES_H)
357 set (ac_cv_have_inttypes_h 1)
358 else (HAVE_INTTYPES_H)
359 set (ac_cv_have_inttypes_h 0)
360 endif (HAVE_INTTYPES_H)
361
362 if (HAVE_LIB_GFLAGS)
363 set (ac_cv_have_libgflags 1)
364 else (HAVE_LIB_GFLAGS)
365 set (ac_cv_have_libgflags 0)
366 endif (HAVE_LIB_GFLAGS)
367
368 if (HAVE_STDINT_H)
369 set (ac_cv_have_stdint_h 1)
370 else (HAVE_STDINT_H)
371 set (ac_cv_have_stdint_h 0)
372 endif (HAVE_STDINT_H)
373
374 if (HAVE_SYS_TYPES_H)
375 set (ac_cv_have_systypes_h 1)
376 else (HAVE_SYS_TYPES_H)
377 set (ac_cv_have_systypes_h 0)
378 endif (HAVE_SYS_TYPES_H)
379
380 if (HAVE_U_INT16_T)
381 set (ac_cv_have_u_int16_t 1)
382 else (HAVE_U_INT16_T)
383 set (ac_cv_have_u_int16_t 0)
384 endif (HAVE_U_INT16_T)
385
386 if (HAVE_UINT16_T)
387 set (ac_cv_have_uint16_t 1)
388 else (HAVE_UINT16_T)
389 set (ac_cv_have_uint16_t 0)
390 endif (HAVE_UINT16_T)
391
392 if (HAVE_UNISTD_H)
393 set (ac_cv_have_unistd_h 1)
394 else (HAVE_UNISTD_H)
395 set (ac_cv_have_unistd_h 0)
396 endif (HAVE_UNISTD_H)
397
398 set (ac_google_namespace ${GOOGLE_NAMESPACE})
399 set (ac_google_end_namespace ${_END_GOOGLE_NAMESPACE_})
400 set (ac_google_start_namespace ${_START_GOOGLE_NAMESPACE_})
401
402 if (HAVE___ATTRIBUTE__)
403 set (ac_cv___attribute___noreturn "__attribute__((noreturn))")
404 set (ac_cv___attribute___noinline "__attribute__((noinline))")
405 set (ac_cv___attribute___printf_4_5 "__attribute__((__format__(__printf__, 4, 5)))")
406 elseif (HAVE___DECLSPEC)
407 set (ac_cv___attribute___noreturn "__declspec(noreturn)")
408 #set (ac_cv___attribute___noinline "__declspec(noinline)")
409 endif (HAVE___ATTRIBUTE__)
410
411 if (HAVE___BUILTIN_EXPECT)
412 set (ac_cv_have___builtin_expect 1)
413 else (HAVE___BUILTIN_EXPECT)
414 set (ac_cv_have___builtin_expect 0)
415 endif (HAVE___BUILTIN_EXPECT)
416
417 if (HAVE_USING_OPERATOR)
418 set (ac_cv_cxx_using_operator 1)
419 else (HAVE_USING_OPERATOR)
420 set (ac_cv_cxx_using_operator 0)
421 endif (HAVE_USING_OPERATOR)
422
423 if (HAVE_CXX11_CONSTEXPR)
424 set (ac_cv_cxx11_constexpr 1)
425 else (HAVE_CXX11_CONSTEXPR)
426 set (ac_cv_cxx11_constexpr 0)
427 endif (HAVE_CXX11_CONSTEXPR)
428
429 if (HAVE_CXX11_CHRONO)
430 set (ac_cv_cxx11_chrono 1)
431 else (HAVE_CXX11_CHRONO)
432 set (ac_cv_cxx11_chrono 0)
433 endif (HAVE_CXX11_CHRONO)
434
435 if (HAVE_CXX11_NULLPTR_T)
436 set (ac_cv_cxx11_nullptr_t 1)
437 else (HAVE_CXX11_NULLPTR_T)
438 set (ac_cv_cxx11_nullptr_t 0)
439 endif (HAVE_CXX11_NULLPTR_T)
440
441 if (HAVE_EXECINFO_H)
442 set (HAVE_STACKTRACE 1)
443 endif (HAVE_EXECINFO_H)
444
445 if (HAVE_CXX11_ATOMIC)
446 set (ac_cv_cxx11_atomic 1)
447 else (HAVE_CXX11_ATOMIC)
448 set (ac_cv_cxx11_atomic 0)
449 endif (HAVE_CXX11_ATOMIC)
450
451 if (WITH_SYMBOLIZE)
452 if (WIN32 OR CYGWIN)
453 cmake_push_check_state (RESET)
454 set (CMAKE_REQUIRED_LIBRARIES DbgHelp)
455
456 check_cxx_source_runs ([=[
457 #include <windows.h>
458 #include <dbghelp.h>
459 #include <cstdlib>
460
461 void foobar() { }
462
463 int main()
464 {
465 HANDLE process = GetCurrentProcess();
466
467 if (!SymInitialize(process, NULL, TRUE))
468 return EXIT_FAILURE;
469
470 char buf[sizeof(SYMBOL_INFO) + MAX_SYM_NAME];
471 SYMBOL_INFO *symbol = reinterpret_cast<SYMBOL_INFO *>(buf);
472 symbol->SizeOfStruct = sizeof(SYMBOL_INFO);
473 symbol->MaxNameLen = MAX_SYM_NAME;
474
475 void* const pc = reinterpret_cast<void*>(&foobar);
476 BOOL ret = SymFromAddr(process, reinterpret_cast<DWORD64>(pc), 0, symbol);
477
478 return ret ? EXIT_SUCCESS : EXIT_FAILURE;
479 }
480 ]=] HAVE_SYMBOLIZE)
481
482 cmake_pop_check_state ()
483
484 if (HAVE_SYMBOLIZE)
485 set (HAVE_STACKTRACE 1)
486 endif (HAVE_SYMBOLIZE)
487 elseif (UNIX OR (APPLE AND HAVE_DLADDR))
488 set (HAVE_SYMBOLIZE 1)
489 endif (WIN32 OR CYGWIN)
490 endif (WITH_SYMBOLIZE)
491
492 # CMake manages symbolize availability. The definition is necessary only when
493 # building the library. Switch to add_compile_definitions once we drop support
494 # for CMake below version 3.12.
495 add_definitions (-DGLOG_NO_SYMBOLIZE_DETECTION)
496
497 check_cxx_source_compiles ("
498 #include <cstdlib>
499 #include <ctime>
500 int main()
501 {
502 time_t timep;
503 struct tm result;
504 localtime_r(&timep, &result);
505 return EXIT_SUCCESS;
506 }
507 " HAVE_LOCALTIME_R)
508
509 set (SIZEOF_VOID_P ${CMAKE_SIZEOF_VOID_P})
510
511 if (WITH_THREADS AND Threads_FOUND)
512 if (CMAKE_USE_PTHREADS_INIT)
513 set (HAVE_PTHREAD 1)
514 endif (CMAKE_USE_PTHREADS_INIT)
515 else (WITH_THREADS AND Threads_FOUND)
516 set (NO_THREADS 1)
517 endif (WITH_THREADS AND Threads_FOUND)
518
519 # fopen/open on Cygwin can not handle unix-type paths like /home/....
520 # therefore we translate TEST_SRC_DIR to windows-path.
521 if (CYGWIN)
522 execute_process (COMMAND cygpath.exe -m ${CMAKE_CURRENT_SOURCE_DIR}
523 OUTPUT_STRIP_TRAILING_WHITESPACE
524 OUTPUT_VARIABLE TEST_SRC_DIR)
525 set (TEST_SRC_DIR \"${TEST_SRC_DIR}\")
526 else (CYGWIN)
527 set (TEST_SRC_DIR \"${CMAKE_CURRENT_SOURCE_DIR}\")
528 endif (CYGWIN)
529
530 configure_file (src/config.h.cmake.in config.h)
531 configure_file (src/glog/logging.h.in glog/logging.h @ONLY)
532 configure_file (src/glog/raw_logging.h.in glog/raw_logging.h @ONLY)
533 configure_file (src/glog/stl_logging.h.in glog/stl_logging.h @ONLY)
534 configure_file (src/glog/vlog_is_on.h.in glog/vlog_is_on.h @ONLY)
535
536 add_compile_options ($<$<AND:$<BOOL:${HAVE_NO_UNNAMED_TYPE_TEMPLATE_ARGS}>,$<NOT:$<CXX_COMPILER_ID:GNU>>>:-Wno-unnamed-type-template-args>)
537
538 set (_glog_CMake_BINDIR ${CMAKE_INSTALL_BINDIR})
539 set (_glog_CMake_INCLUDE_DIR ${CMAKE_INSTALL_INCLUDEDIR})
540 set (_glog_CMake_LIBDIR ${CMAKE_INSTALL_LIBDIR})
541 set (_glog_CMake_INSTALLDIR ${_glog_CMake_LIBDIR}/cmake/glog)
542
543 set (_glog_CMake_DIR glog/cmake)
544 set (_glog_CMake_DATADIR ${CMAKE_INSTALL_DATAROOTDIR}/${_glog_CMake_DIR})
545 set (_glog_BINARY_CMake_DATADIR
546 ${CMAKE_CURRENT_BINARY_DIR}/${_glog_CMake_DATADIR})
547
548 # Add additional CMake find modules here.
549 set (_glog_CMake_MODULES)
550
551 if (Unwind_FOUND)
552 # Copy the module only if libunwind is actually used.
553 list (APPEND _glog_CMake_MODULES ${CMAKE_CURRENT_SOURCE_DIR}/cmake/FindUnwind.cmake)
554 endif (Unwind_FOUND)
555
556 # Generate file name for each module in the binary directory
557 foreach (_file ${_glog_CMake_MODULES})
558 get_filename_component (_module "${_file}" NAME)
559
560 list (APPEND _glog_BINARY_CMake_MODULES
561 ${_glog_BINARY_CMake_DATADIR}/${_module})
562 endforeach (_file)
563
564 if (_glog_CMake_MODULES)
565 # Copy modules to binary directory during the build
566 add_custom_command (OUTPUT ${_glog_BINARY_CMake_MODULES}
567 COMMAND ${CMAKE_COMMAND} -E make_directory
568 ${_glog_BINARY_CMake_DATADIR}
569 COMMAND ${CMAKE_COMMAND} -E copy ${_glog_CMake_MODULES}
570 ${_glog_BINARY_CMake_DATADIR}
571 DEPENDS ${_glog_CMake_MODULES}
572 COMMENT "Copying find modules..."
573 )
574 endif (_glog_CMake_MODULES)
575
576 set (GLOG_PUBLIC_H
577 ${CMAKE_CURRENT_BINARY_DIR}/glog/export.h
578 ${CMAKE_CURRENT_BINARY_DIR}/glog/logging.h
579 ${CMAKE_CURRENT_BINARY_DIR}/glog/raw_logging.h
580 ${CMAKE_CURRENT_BINARY_DIR}/glog/stl_logging.h
581 ${CMAKE_CURRENT_BINARY_DIR}/glog/vlog_is_on.h
582 src/glog/log_severity.h
583 src/glog/platform.h
584 )
585
586 set (GLOG_SRCS
587 ${GLOG_PUBLIC_H}
588 src/base/commandlineflags.h
589 src/base/googleinit.h
590 src/base/mutex.h
591 src/demangle.cc
592 src/demangle.h
593 src/logging.cc
594 src/raw_logging.cc
595 src/symbolize.cc
596 src/symbolize.h
597 src/utilities.cc
598 src/utilities.h
599 src/vlog_is_on.cc
600 )
601
602 if (HAVE_PTHREAD OR WIN32 OR CYGWIN)
603 list (APPEND GLOG_SRCS src/signalhandler.cc)
604 endif (HAVE_PTHREAD OR WIN32 OR CYGWIN)
605
606 if (CYGWIN OR WIN32)
607 list (APPEND GLOG_SRCS
608 src/windows/port.cc
609 src/windows/port.h
610 )
611 endif (CYGWIN OR WIN32)
612
613 add_library (glogbase OBJECT
614 ${_glog_BINARY_CMake_MODULES}
615 ${GLOG_SRCS}
616 )
617
618 add_library (glog
619 $<TARGET_OBJECTS:glogbase>
620 )
621
622 add_library (glog::glog ALIAS glog)
623
624 set (glog_libraries_options_for_static_linking)
625
626 if (Unwind_FOUND)
627 target_link_libraries (glog PRIVATE unwind::unwind)
628 set (glog_libraries_options_for_static_linking "${glog_libraries_options_for_static_linking} -lunwind")
629 set (Unwind_DEPENDENCY "find_dependency (Unwind ${Unwind_VERSION})")
630 endif (Unwind_FOUND)
631
632 if (HAVE_DBGHELP)
633 target_link_libraries (glog PRIVATE dbghelp)
634 set (glog_libraries_options_for_static_linking "${glog_libraries_options_for_static_linking} -ldbghelp")
635 endif (HAVE_DBGHELP)
636
637 if (HAVE_PTHREAD)
638 target_link_libraries (glog PRIVATE ${CMAKE_THREAD_LIBS_INIT})
639
640 if (CMAKE_THREAD_LIBS_INIT)
641 set (glog_libraries_options_for_static_linking "${glog_libraries_options_for_static_linking} ${CMAKE_THREAD_LIBS_INIT}")
642 endif (CMAKE_THREAD_LIBS_INIT)
643 endif (HAVE_PTHREAD)
644
645 if (gflags_FOUND)
646 # Prefer the gflags target that uses double colon convention
647 if (TARGET gflags::gflags)
648 target_link_libraries (glog PUBLIC gflags::gflags)
649 else (TARGET gflags::gflags)
650 target_link_libraries (glog PUBLIC gflags)
651 endif (TARGET gflags::gflags)
652
653 set (glog_libraries_options_for_static_linking "${glog_libraries_options_for_static_linking} -lgflags")
654 endif (gflags_FOUND)
655
656 if (ANDROID)
657 target_link_libraries (glog PRIVATE log)
658 set (glog_libraries_options_for_static_linking "${glog_libraries_options_for_static_linking} -llog")
659 endif (ANDROID)
660
661 set_target_properties (glog PROPERTIES VERSION ${PROJECT_VERSION})
662 set_target_properties (glog PROPERTIES SOVERSION 1)
663
664 if (CYGWIN OR WIN32)
665 target_compile_definitions (glog PUBLIC GLOG_NO_ABBREVIATED_SEVERITIES)
666 endif (CYGWIN OR WIN32)
667
668 if (WITH_CUSTOM_PREFIX)
669 target_compile_definitions (glog PUBLIC GLOG_CUSTOM_PREFIX_SUPPORT)
670 endif (WITH_CUSTOM_PREFIX)
671
672 set_target_properties (glog PROPERTIES PUBLIC_HEADER "${GLOG_PUBLIC_H}")
673
674 target_include_directories (glog BEFORE PUBLIC
675 "$<BUILD_INTERFACE:${CMAKE_CURRENT_BINARY_DIR}>"
676 "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src>"
677 "$<INSTALL_INTERFACE:${_glog_CMake_INCLUDE_DIR}>"
678 PRIVATE ${CMAKE_CURRENT_BINARY_DIR}
679 PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/src)
680
681 if (CYGWIN OR WIN32)
682 target_include_directories (glogbase PUBLIC
683 "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/windows>"
684 PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/src/windows)
685
686 target_include_directories (glog PUBLIC
687 "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/src/windows>"
688 PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}/src/windows)
689 endif (CYGWIN OR WIN32)
690
691 set_target_properties (glog PROPERTIES DEFINE_SYMBOL GOOGLE_GLOG_IS_A_DLL)
692
693 target_include_directories (glogbase PUBLIC
694 $<TARGET_PROPERTY:glog,INCLUDE_DIRECTORIES>)
695 target_compile_definitions (glogbase PUBLIC
696 $<TARGET_PROPERTY:glog,COMPILE_DEFINITIONS>
697 PRIVATE GOOGLE_GLOG_IS_A_DLL)
698
699 generate_export_header (glog
700 EXPORT_MACRO_NAME GLOG_EXPORT
701 EXPORT_FILE_NAME ${CMAKE_CURRENT_BINARY_DIR}/glog/export.h)
702
703 string (STRIP "${glog_libraries_options_for_static_linking}" glog_libraries_options_for_static_linking)
704
705 if (WITH_PKGCONFIG)
706 set (VERSION ${PROJECT_VERSION})
707 set (prefix ${CMAKE_INSTALL_PREFIX})
708 set (exec_prefix ${CMAKE_INSTALL_FULL_BINDIR})
709 set (libdir ${CMAKE_INSTALL_FULL_LIBDIR})
710 set (includedir ${CMAKE_INSTALL_FULL_INCLUDEDIR})
711
712 configure_file (
713 "${PROJECT_SOURCE_DIR}/libglog.pc.in"
714 "${PROJECT_BINARY_DIR}/libglog.pc"
715 @ONLY
716 )
717
718 unset (VERSION)
719 unset (prefix)
720 unset (exec_prefix)
721 unset (libdir)
722 unset (includedir)
723 endif (WITH_PKGCONFIG)
724
725 # Unit testing
726
727 if (BUILD_TESTING)
728 add_library (glogtest STATIC
729 $<TARGET_OBJECTS:glogbase>
730 )
731
732 target_include_directories (glogtest PUBLIC
733 $<TARGET_PROPERTY:glog,INCLUDE_DIRECTORIES>)
734 target_compile_definitions (glogtest PUBLIC
735 $<TARGET_PROPERTY:glog,COMPILE_DEFINITIONS> GLOG_STATIC_DEFINE)
736 target_link_libraries (glogtest PUBLIC
737 $<TARGET_PROPERTY:glog,LINK_LIBRARIES>)
738
739 set (_GLOG_TEST_LIBS glogtest)
740
741 if (HAVE_LIB_GTEST)
742 list (APPEND _GLOG_TEST_LIBS GTest::gtest)
743 endif (HAVE_LIB_GTEST)
744
745 if (HAVE_LIB_GMOCK)
746 list (APPEND _GLOG_TEST_LIBS GTest::gmock)
747 endif (HAVE_LIB_GMOCK)
748
749 add_executable (logging_unittest
750 src/logging_unittest.cc
751 )
752
753 target_link_libraries (logging_unittest PRIVATE ${_GLOG_TEST_LIBS})
754
755 if (WITH_CUSTOM_PREFIX)
756 add_executable (logging_custom_prefix_unittest
757 src/logging_custom_prefix_unittest.cc
758 )
759
760 target_link_libraries (logging_custom_prefix_unittest PRIVATE ${_GLOG_TEST_LIBS})
761
762 add_test (NAME logging_custom_prefix
763 COMMAND logging_custom_prefix_unittest)
764
765 # FIXME: Skip flaky test
766 set_tests_properties (logging_custom_prefix PROPERTIES SKIP_REGULAR_EXPRESSION
767 "Check failed: time_ns within LogTimes::LOG_PERIOD_TOL_NS of LogTimes::LOG_PERIOD_NS")
768
769 if (APPLE)
770 # FIXME: Skip flaky test
771 set_property (TEST logging_custom_prefix APPEND PROPERTY SKIP_REGULAR_EXPRESSION
772 "unexpected new.*PASS\nTest with golden file failed. We'll try to show the diff:")
773 endif (APPLE)
774 endif (WITH_CUSTOM_PREFIX)
775
776 add_executable (stl_logging_unittest
777 src/stl_logging_unittest.cc
778 )
779
780 target_link_libraries (stl_logging_unittest PRIVATE ${_GLOG_TEST_LIBS})
781
782 if (HAVE_NO_DEPRECATED)
783 set_property (TARGET stl_logging_unittest APPEND PROPERTY COMPILE_OPTIONS
784 -Wno-deprecated)
785 endif (HAVE_NO_DEPRECATED)
786
787 if (HAVE_UNORDERED_MAP AND HAVE_UNORDERED_SET)
788 target_compile_definitions (stl_logging_unittest PRIVATE
789 GLOG_STL_LOGGING_FOR_UNORDERED)
790 endif (HAVE_UNORDERED_MAP AND HAVE_UNORDERED_SET)
791
792 if (HAVE_TR1_UNORDERED_MAP AND HAVE_TR1_UNORDERED_SET)
793 target_compile_definitions (stl_logging_unittest PRIVATE
794 GLOG_STL_LOGGING_FOR_TR1_UNORDERED)
795 endif (HAVE_TR1_UNORDERED_MAP AND HAVE_TR1_UNORDERED_SET)
796
797 if (HAVE_EXT_HASH_MAP AND HAVE_EXT_HASH_SET)
798 target_compile_definitions (stl_logging_unittest PRIVATE
799 GLOG_STL_LOGGING_FOR_EXT_HASH)
800 endif (HAVE_EXT_HASH_MAP AND HAVE_EXT_HASH_SET)
801
802 if (HAVE_EXT_SLIST)
803 target_compile_definitions (stl_logging_unittest PRIVATE
804 GLOG_STL_LOGGING_FOR_EXT_SLIST)
805 endif (HAVE_EXT_SLIST)
806
807 if (HAVE_SYMBOLIZE)
808 add_executable (symbolize_unittest
809 src/symbolize_unittest.cc
810 )
811
812 target_link_libraries (symbolize_unittest PRIVATE ${_GLOG_TEST_LIBS})
813 endif (HAVE_SYMBOLIZE)
814
815 add_executable (demangle_unittest
816 src/demangle_unittest.cc
817 )
818
819 target_link_libraries (demangle_unittest PRIVATE ${_GLOG_TEST_LIBS})
820
821 if (HAVE_STACKTRACE)
822 add_executable (stacktrace_unittest
823 src/stacktrace_unittest.cc
824 )
825
826 target_link_libraries (stacktrace_unittest PRIVATE ${_GLOG_TEST_LIBS})
827 endif (HAVE_STACKTRACE)
828
829 add_executable (utilities_unittest
830 src/utilities_unittest.cc
831 )
832
833 target_link_libraries (utilities_unittest PRIVATE ${_GLOG_TEST_LIBS})
834
835 if (HAVE_STACKTRACE AND HAVE_SYMBOLIZE)
836 add_executable (signalhandler_unittest
837 src/signalhandler_unittest.cc
838 )
839
840 target_link_libraries (signalhandler_unittest PRIVATE ${_GLOG_TEST_LIBS})
841 endif (HAVE_STACKTRACE AND HAVE_SYMBOLIZE)
842
843 add_test (NAME demangle COMMAND demangle_unittest)
844 add_test (NAME logging COMMAND logging_unittest)
845
846 set_tests_properties (logging PROPERTIES TIMEOUT 30)
847
848 # FIXME: Skip flaky test
849 set_tests_properties (logging PROPERTIES SKIP_REGULAR_EXPRESSION
850 "Check failed: time_ns within LogTimes::LOG_PERIOD_TOL_NS of LogTimes::LOG_PERIOD_NS")
851
852 if (APPLE)
853 # FIXME: Skip flaky test
854 set_property (TEST logging APPEND PROPERTY SKIP_REGULAR_EXPRESSION
855 "unexpected new.*PASS\nTest with golden file failed. We'll try to show the diff:")
856 endif (APPLE)
857
858 if (TARGET signalhandler_unittest)
859 add_test (NAME signalhandler COMMAND signalhandler_unittest)
860 endif (TARGET signalhandler_unittest)
861
862 if (TARGET stacktrace_unittest)
863 add_test (NAME stacktrace COMMAND stacktrace_unittest)
864 set_tests_properties (stacktrace PROPERTIES TIMEOUT 30)
865 endif (TARGET stacktrace_unittest)
866
867 add_test (NAME stl_logging COMMAND stl_logging_unittest)
868
869 if (TARGET symbolize_unittest)
870 add_test (NAME symbolize COMMAND symbolize_unittest)
871 endif (TARGET symbolize_unittest)
872
873 if (HAVE_LIB_GMOCK)
874 add_executable (mock-log_unittest
875 src/mock-log_unittest.cc
876 src/mock-log.h
877 )
878
879 target_link_libraries (mock-log_unittest PRIVATE ${_GLOG_TEST_LIBS})
880
881 add_test (NAME mock-log COMMAND mock-log_unittest)
882 endif (HAVE_LIB_GMOCK)
883
884 # Generate an initial cache
885
886 get_cache_variables (_CACHEVARS)
887
888 set (_INITIAL_CACHE
889 ${CMAKE_CURRENT_BINARY_DIR}/test_package_config/glog_package_config_initial_cache.cmake)
890
891 # Package config test
892
893 add_test (NAME cmake_package_config_init COMMAND ${CMAKE_COMMAND}
894 -DTEST_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}/test_package_config
895 -DINITIAL_CACHE=${_INITIAL_CACHE}
896 -DCACHEVARS=${_CACHEVARS}
897 -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/TestInitPackageConfig.cmake
898 )
899
900 add_test (NAME cmake_package_config_generate COMMAND ${CMAKE_COMMAND}
901 -DGENERATOR=${CMAKE_GENERATOR}
902 -DGENERATOR_PLATFORM=${CMAKE_GENERATOR_PLATFORM}
903 -DGENERATOR_TOOLSET=${CMAKE_GENERATOR_TOOLSET}
904 -DINITIAL_CACHE=${_INITIAL_CACHE}
905 -DPACKAGE_DIR=${CMAKE_CURRENT_BINARY_DIR}
906 -DPATH=$ENV{PATH}
907 -DSOURCE_DIR=${CMAKE_CURRENT_SOURCE_DIR}/src/package_config_unittest/working_config
908 -DTEST_BINARY_DIR=${CMAKE_CURRENT_BINARY_DIR}/test_package_config/working_config
909 -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/TestPackageConfig.cmake
910 )
911
912 add_test (NAME cmake_package_config_build COMMAND
913 ${CMAKE_COMMAND} --build ${CMAKE_CURRENT_BINARY_DIR}/test_package_config/working_config
914 --config $<CONFIG>
915 )
916
917 add_test (NAME cmake_package_config_cleanup COMMAND ${CMAKE_COMMAND} -E
918 remove_directory
919 ${CMAKE_CURRENT_BINARY_DIR}/test_package_config
920 )
921
922 # Fixtures setup
923 set_tests_properties (cmake_package_config_init PROPERTIES FIXTURES_SETUP
924 cmake_package_config)
925 set_tests_properties (cmake_package_config_generate PROPERTIES FIXTURES_SETUP
926 cmake_package_config_working)
927
928 # Fixtures cleanup
929 set_tests_properties (cmake_package_config_cleanup PROPERTIES FIXTURES_CLEANUP
930 cmake_package_config)
931
932 # Fixture requirements
933 set_tests_properties (cmake_package_config_generate PROPERTIES
934 FIXTURES_REQUIRED cmake_package_config)
935 set_tests_properties (cmake_package_config_build PROPERTIES
936 FIXTURES_REQUIRED "cmake_package_config;cmake_package_config_working")
937
938 add_executable (cleanup_immediately_unittest
939 src/cleanup_immediately_unittest.cc)
940
941 target_link_libraries (cleanup_immediately_unittest PRIVATE ${_GLOG_TEST_LIBS})
942
943 add_executable (cleanup_with_absolute_prefix_unittest
944 src/cleanup_with_absolute_prefix_unittest.cc)
945
946 target_link_libraries (cleanup_with_absolute_prefix_unittest PRIVATE ${_GLOG_TEST_LIBS})
947
948 add_executable (cleanup_with_relative_prefix_unittest
949 src/cleanup_with_relative_prefix_unittest.cc)
950
951 target_link_libraries (cleanup_with_relative_prefix_unittest PRIVATE ${_GLOG_TEST_LIBS})
952
953 set (CLEANUP_LOG_DIR ${CMAKE_CURRENT_BINARY_DIR}/cleanup_tests)
954
955 add_test (NAME cleanup_init COMMAND
956 ${CMAKE_COMMAND} -E make_directory ${CLEANUP_LOG_DIR})
957 add_test (NAME cleanup_logdir COMMAND
958 ${CMAKE_COMMAND} -E remove_directory ${CLEANUP_LOG_DIR})
959 add_test (NAME cleanup_immediately COMMAND
960 ${CMAKE_COMMAND}
961 -DLOGCLEANUP=$<TARGET_FILE:cleanup_immediately_unittest>
962 # NOTE The trailing slash is important
963 -DTEST_DIR=${CLEANUP_LOG_DIR}/
964 -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/RunCleanerTest1.cmake
965 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
966 add_test (NAME cleanup_with_absolute_prefix COMMAND
967 ${CMAKE_COMMAND}
968 -DLOGCLEANUP=$<TARGET_FILE:cleanup_with_absolute_prefix_unittest>
969 -DTEST_DIR=${CMAKE_CURRENT_BINARY_DIR}/
970 -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/RunCleanerTest2.cmake
971 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
972 add_test (NAME cleanup_with_relative_prefix COMMAND
973 ${CMAKE_COMMAND}
974 -DLOGCLEANUP=$<TARGET_FILE:cleanup_with_relative_prefix_unittest>
975 -DTEST_DIR=${CMAKE_CURRENT_BINARY_DIR}/
976 -DTEST_SUBDIR=test_subdir/
977 -P ${CMAKE_CURRENT_SOURCE_DIR}/cmake/RunCleanerTest3.cmake
978 WORKING_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
979
980 # Fixtures setup
981 set_tests_properties (cleanup_init PROPERTIES FIXTURES_SETUP logcleanuptest)
982 ## Fixtures cleanup
983 set_tests_properties (cleanup_logdir PROPERTIES FIXTURES_CLEANUP logcleanuptest)
984 # Fixture requirements
985 set_tests_properties (cleanup_immediately PROPERTIES FIXTURES_REQUIRED logcleanuptest)
986 set_tests_properties (cleanup_with_absolute_prefix PROPERTIES FIXTURES_REQUIRED logcleanuptest)
987 set_tests_properties (cleanup_with_relative_prefix PROPERTIES FIXTURES_REQUIRED logcleanuptest)
988 endif (BUILD_TESTING)
989
990 install (TARGETS glog
991 EXPORT glog-targets
992 RUNTIME DESTINATION ${_glog_CMake_BINDIR}
993 PUBLIC_HEADER DESTINATION ${_glog_CMake_INCLUDE_DIR}/glog
994 LIBRARY DESTINATION ${_glog_CMake_LIBDIR}
995 ARCHIVE DESTINATION ${_glog_CMake_LIBDIR})
996
997 if (WITH_PKGCONFIG)
998 install (
999 FILES "${PROJECT_BINARY_DIR}/libglog.pc"
1000 DESTINATION "${_glog_CMake_LIBDIR}/pkgconfig"
1001 )
1002 endif (WITH_PKGCONFIG)
1003
1004 set (glog_CMake_VERSION 3.0)
1005
1006 if (gflags_FOUND)
1007 # Ensure clients locate only the package config and not third party find
1008 # modules having the same name. This avoid cmake_policy PUSH/POP errors.
1009 if (CMAKE_VERSION VERSION_LESS 3.9)
1010 set (gflags_DEPENDENCY "find_dependency (gflags ${gflags_VERSION})")
1011 else (CMAKE_VERSION VERSION_LESS 3.9)
1012 # Passing additional find_package arguments to find_dependency is possible
1013 # starting with CMake 3.9.
1014 set (glog_CMake_VERSION 3.9)
1015 set (gflags_DEPENDENCY "find_dependency (gflags ${gflags_VERSION} NO_MODULE)")
1016 endif (CMAKE_VERSION VERSION_LESS 3.9)
1017 endif (gflags_FOUND)
1018
1019 configure_package_config_file (glog-config.cmake.in
1020 ${CMAKE_CURRENT_BINARY_DIR}/glog-config.cmake
1021 INSTALL_DESTINATION ${_glog_CMake_INSTALLDIR}
1022 NO_CHECK_REQUIRED_COMPONENTS_MACRO)
1023
1024 write_basic_package_version_file (
1025 ${CMAKE_CURRENT_BINARY_DIR}/glog-config-version.cmake
1026 COMPATIBILITY SameMajorVersion)
1027
1028 export (TARGETS glog NAMESPACE glog:: FILE glog-targets.cmake)
1029 export (PACKAGE glog)
1030
1031 get_filename_component (_PREFIX "${CMAKE_INSTALL_PREFIX}" ABSOLUTE)
1032
1033 # Directory containing the find modules relative to the config install
1034 # directory.
1035 file (RELATIVE_PATH glog_REL_CMake_MODULES
1036 ${_PREFIX}/${_glog_CMake_INSTALLDIR}
1037 ${_PREFIX}/${_glog_CMake_DATADIR}/glog-modules.cmake)
1038
1039 get_filename_component (glog_REL_CMake_DATADIR ${glog_REL_CMake_MODULES}
1040 DIRECTORY)
1041
1042 set (glog_FULL_CMake_DATADIR
1043 ${CMAKE_CURRENT_BINARY_DIR}/${_glog_CMake_DATADIR})
1044
1045 configure_file (glog-modules.cmake.in
1046 ${CMAKE_CURRENT_BINARY_DIR}/glog-modules.cmake @ONLY)
1047
1048 install (CODE
1049 "
1050 set (glog_FULL_CMake_DATADIR \"\\\${CMAKE_CURRENT_LIST_DIR}/${glog_REL_CMake_DATADIR}\")
1051 set (glog_DATADIR_DESTINATION ${_glog_CMake_INSTALLDIR})
1052
1053 if (NOT IS_ABSOLUTE ${_glog_CMake_INSTALLDIR})
1054 set (glog_DATADIR_DESTINATION \"\${CMAKE_INSTALL_PREFIX}/\${glog_DATADIR_DESTINATION}\")
1055 endif (NOT IS_ABSOLUTE ${_glog_CMake_INSTALLDIR})
1056
1057 configure_file (\"${CMAKE_CURRENT_SOURCE_DIR}/glog-modules.cmake.in\"
1058 \"${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/glog-modules.cmake\" @ONLY)
1059 file (INSTALL
1060 \"${CMAKE_CURRENT_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/glog-modules.cmake\"
1061 DESTINATION
1062 \"\${glog_DATADIR_DESTINATION}\")
1063 "
1064 COMPONENT Development
1065 )
1066
1067 install (FILES
1068 ${CMAKE_CURRENT_BINARY_DIR}/glog-config.cmake
1069 ${CMAKE_CURRENT_BINARY_DIR}/glog-config-version.cmake
1070 DESTINATION ${_glog_CMake_INSTALLDIR})
1071
1072 # Find modules in share/glog/cmake
1073 install (DIRECTORY ${_glog_BINARY_CMake_DATADIR}
1074 DESTINATION ${CMAKE_INSTALL_DATAROOTDIR}/glog
1075 COMPONENT Development
1076 FILES_MATCHING PATTERN "*.cmake"
1077 )
1078
1079 install (EXPORT glog-targets NAMESPACE glog:: DESTINATION
1080 ${_glog_CMake_INSTALLDIR})